# ~/monks/1209129.t

package MyTypes {
    use parent 'Type::Library';
    use Type::Utils;
    use Types::Standard qw/ ArrayRef Dict Enum Str StrMatch /;

    my $MyArray = Type::Tiny->new(
        as         => 'ArrayRef',
        name       => 'ClientArray',
        constraint => sub { scalar @{ $_ } == 2 },
    );

    declare MyType => as Dict[
        method    => Enum['xxx'],
        backend   => Dict[
            client => StrMatch[qr/\d{3}/],
            pw     => Str,
        ],
        clientArr => $MyArray,
    ];

    # If you want to be able to use the new type independently by name:
    __PACKAGE__->meta->add_type($MyArray);
    __PACKAGE__->meta->make_immutable;
};

package main {
    use Test::Most;
    use JSON;

    # normally, load as normal with `use MyTypes '+MyType'`
    MyTypes->import(qw/ +MyType /);

    while ( <DATA> ) {
        my ( $label, $json ) = split / => /;
        chomp $json;
        my $data = from_json $json;
        if ( $. == 1 ) {
            ok eval { assert_MyType( $data ); 1 }, $label;
        } else {
            ok ! eval { assert_MyType( $data ); 1 }, $label;
        }
    }

    done_testing;
};

__END__
Valid data => {"method":"xxx","backend":{"client":"mytest009","pw":"sdkjfhsfjhKJH87"},"clientArr":[{"num":"1"},{"num":"2"}]}
Unknown key => {"method":"xxx","backend":{"client":"mytest009","pw":"sdkjfhsfjhKJH87"},"clientArr":[{"num":"1"},{"num":"2"}],"blah":"123"}
Failed regexp => {"method":"xxx","backend":{"client":"mytest09","pw":"sdkjfhsfjhKJH87"},"clientArr":[{"num":"1"},{"num":"2"}]}
Not an array => {"method":"xxx","backend":{"client":"mytest009","pw":"sdkjfhsfjhKJH87"},"clientArr":{"foo":{"num":"1"},"bar":{"num":"2"}}}
Array too long => {"method":"xxx","backend":{"client":"mytest009","pw":"sdkjfhsfjhKJH87"},"clientArr":[{"num":"1"},{"num":"2"},{"num":"3"}]}