#! perl -slw
use strict;
use List::Util qw[ reduce ]; $a = $b;
use constant DICTIONARY => 'dictionary.txt';

my %mappings;
reduce{
  $mappings{ $_ } = $a for split '', $b;
  $a + 1;
} 0, qw[ e jnq rwx dsy ft am civ bku lop ghz ];

my %dict = map{ $_ => [ $_ ] } 0 .. 9;
keys %dict = 300000;

open DICT, '<', DICTIONARY or die "${\DICTIONARY}: $!";
while( <DICT> ) {
    chomp;
    my $orig = $_;
    tr[A-Z"/-][a-z]d; #"
    push @{ $dict{ join '', @mappings{ split '', $_ } } }, $orig;
}
close DICT;

sub encode {
    my $number = shift;
    my $start = length( $number );
    --$start while $start and not exists $dict{ substr $number, 0, $start };
    $start = 2 if $start > 1;

    return @{ $dict{ $number } || [] }, grep !/\d \d/, map {
        my( $pre, $post ) = unpack "a$_ a*", $number;
        map{
            my $head = $_;
            map "$head $_", encode( $post );
        } @{ $dict{ $pre } || [] },
    } $start .. length( $number )-1;
}

while( <> ) {
    chomp;
    my $orig = $_;
    tr[/-][]d;
    print "$orig: $_" for encode( $_ );
}