Finding the exact point of intersection is too much work if
all we care about is whether two lines intersect at all. 
The intersection, if any, can be found by examining the 
signs of the two cross products 
(p2 - p0) × (p1 - p0) and (p3 - p0)× (p1 - p0).
The line_intersect() subroutine returns a simple true or
false value indicating whether two lines intersect:

# line_intersect( $x0, $y0, $x1, $y1, $x2, $y2, $x3, $y3 )
# Returns true if the two lines defined by these points intersect.
# In borderline cases, it relies on epsilon to decide.
 sub line_intersect {
  my ( $x0, $y0, $x1, $y1, $x2, $y2, $x3, $y3 ) = @_;
  my @box_a = bounding_box( 2, $x0, $y0, $x1, $y1 );
  my @box_b = bounding_box( 2, $x2, $y2, $x3, $y3 );
  # If even the bounding boxes do not intersect, give up right now.
  return 0 unless bounding_box_intersect( 2, @box_a, @box_b );
  # If the signs of the two determinants (absolute values or lengths
  # of the cross products, actually) are different, the lines
  # intersect.
  my $dx10 = $x1 - $x0;
  my $dy10 = $y1 - $y0;
  my $det_a = determinant( $x2 - $x0, $y2 - $y0, $dx10, $dy10 );
  my $det_b = determinant( $x3 - $x0, $y3 - $y0, $dx10, $dy10 );
  return 1 if $det_a < 0 and $det_b > 0 or
  $det_a > 0 and $det_b < 0;
  if ( abs( $det_a ) < epsilon ) {
   if ( abs( $det_b ) < epsilon ) {
    # Both cross products are "zero".
    return 1;
   } elsif (abs($x3-$x2)<epsilon and abs($y3-$y2)<epsilon){
     # The other cross product is "zero" and
     # the other vector (from (x2,y2) to (x3,y3))
     # is also "zero".
    return 1;
   }
  } elsif ( abs( $det_b < epsilon ) ) {
  # The other cross product is "zero" and
  # the other vector is also "zero".
  return 1 if abs( $dx10 ) < epsilon and abs( $dy10 ) < epsilon;
 }
 return 0; # Default is no intersection.
}

# determinant( $x0, $y0, $x1, $y1 )    [from p. 432]
# Computes the determinant given the four elements of a matrix
# as arguments.
#
sub determinant { $_[0] * $_[3] - $_[1] * $_[2] }