#!/usr/bin/perl -w
use Crypt::OpenPGP;
use Crypt::OpenPGP::KeyRing;

my($keyfile, $email) = @ARGV;
my $ring = Crypt::OpenPGP::KeyRing->new(Filename => $keyfile);
my $pgp = Crypt::OpenPGP->new(PubRing => $ring);
my $kb = $ring->find_keyblock_by_uid($email);
my $alg = $kb->preferred_sk_alg;
my $crypt = $pgp->encrypt(
    Data => 'squeamish ossifrage',
    Recipients => [ $email ],
    Armour => 1,
    ($alg ? (Cipher => $alg) : ()), # use default if no preference located
);
print $crypt;
exit 0;

{
    package Crypt::OpenPGP::KeyBlock;
    sub preferred_sk_alg {
        my $self = shift;
        use Crypt::OpenPGP::Cipher;
        my $supported = Crypt::OpenPGP::Cipher->supported;
        my @prefs;
        for my $sig (@{ $self->get('Crypt::OpenPGP::Signature') }) {
            if ($sig->is_primary) {
                unshift @prefs, @{ $sig->preferred_sk_alg };
            } else {
                push @prefs, @{ $sig->preferred_sk_alg };
            }
        }
        for (@prefs) {
            return $_ if $supported->{$_};
        }
        return;
    }
}
{
    package Crypt::OpenPGP::Signature;
    sub is_primary {
        my $self = shift;
        my $packet = $self->find_subpacket(25); # primary user id
        ($packet && $packet->{data}) || 0;
    }
    sub preferred_sk_alg {
        my $self = shift;
        my $packet = $self->find_subpacket(11); # preferred SK algorithms
        $packet ? $packet->{data} : [];
    }
}