#!/usr/bin/perl
use strict;
use warnings;

my @files = glob "/usr/share/applications/*.desktop";
my $regex = join "|", qw/ Audio Graphics Network Settings System Utility /;
my %data;

FILE: for my $file (@files) {
	open my $fh, "<", $file or die "Unable to open $file (for reading). $!";
	my ($category, $name, $exec);
	while (<$fh>) {
		if(/^Categories=.*?\b($regex)\b/) {
			$category ||= $1; # sets cat for first time only (each file)
		}
		elsif (/^Name=(.+)$/) {
			$name ||= $1;	  # sets name first time only (each file)
		}
		elsif (/^Exec=(\S+)/) {
			$exec ||= $1;	  # sets exec first time only (each file)
		}
	}
	close $fh or die "Unable to close $file. $!";
	for ($category, $name, $exec) {
		if (! defined) {
			warn "$file missing category or name or exec.\n";
			# skip the 'push' below and go to the label 'FILE:'
			next FILE;
		}
	}
	push @{ $data{ $category } }, {name => $name, exec => $exec};	
}

for my $category (keys %data) {
	print "Submenu = \"$category\" {\n";
	my @recs = @{ $data{ $category } };
	for my $href ( @recs ) { # hash reference
		print "     Entry = \"$href->{name}\" { Actions = \"$href->{exec}\" }\n";
	}
	print "}\n";
}