Re: Constants and Subclasses...

[t'mo]

Thanks for the suggestions. My code is evolving somewhat differently than the suggested code (mostly to avoid the duplication implicit in both use const NAME and putting NAME in @EXPORT). I agree that it's unfortunate that the namespace is polluted via all the Exporter stuff, but hey, it works. (Note: ParentClass is defined in another file, I just didn't mention it before.)

package ParentClass;
BEGIN {
  my %constants = (
    FOO => 'foo',
    BAR => 'bar',
    BAZ => 'baz',
  );
  foreach my $name ( keys %constants ) {
    no strict 'refs';
    *{$name} = sub () { $constants{$name} };
  }
  our @EXPORT = keys %constants;
}

# -------- new file --------

package ChildClass;
use base 'ParentClass';
BEGIN {
  ParentClass->import();
}
sub doStuff {
  my ($self, @otherArguments) = @_;
  print FOO; # Yay, it works this time!
  ...
}

Edit: changed scalar constants to hash.

[diotalevi]

You wrote:

BEGIN {
  my $constants = (
    FOO => 'foo',
    BAR => 'bar',
    BAZ => 'baz',
  );
  foreach my $name ( keys %constants ) {
    no strict 'refs';
    *{$name} = sub () { $constants{$name} };
  }
  ...
}</blockquote>

If you're going to make constants, do them the proper way with the constant pragma. What you wrote is roughly how constant.pm works in versions prior to 5.9 but the next versions of perl have a different implementation for constant and you'll want your code to do the right thing regardless.

BEGIN {
    require constant;
    my %constants = (
        FOO => 'foo',
        BAR => 'bar',
        BAZ => 'baz',
    );
    foreach my $name ( keys %constants ) {
        constant->import( $name => $constants{$name} );
    }
}

You also goofed and made a variable $constants instead of %constants.

[t'mo]

Cool, I didn't realize you could constant->import. I had tried to use constant NAME => value inside that loop, but (obviously) it didn't work.

[diotalevi]

Well sure. use constant FOO => 'bar'; is just shorthand for the following:

BEGIN {
    require constant;
    constant->import( FOO => 'bar' );
}