Re^4: How do I make the garbage collector throw an exception when it fails to auto-close a filehandle?

[Aristotle]

That seems to be the only reliable approach. You don’t even need to load IO::Handle. However, I can’t actually get it to complain:

use strict;

sub IO::Handle::DESTROY {
    my $self = shift;
    warn +(caller 0)[3]."($self)\n";
    close $self or die "$!\n";
}

{ if( open my $fh, ">", "/dev/full" ) { print { $fh } 1 } }

warn "Terminating\n";
__END__
IO::Handle::DESTROY(IO::Handle=IO(0x8130c0c))
Terminating

The error does occur: if I change the die to a warn, I see the warning. But while die aborts execution (statements after it will not run), I can’t make it throw an exception. The conditions from Carping in DESTROY, which was mentioned in another subthread, do not apply either.

[mr_mischief]

die() doesn't work, but exit() still does. I tried this, with good results:

#!/usr/bin/perl
use strict;
use warnings;


$| = 1;

sub IO::Handle::DESTROY {
    print "desctructor enter\n";
    my $self = shift;
    close $self or do {
        warn $!;
        exit;
    };
    print "destructor exit\n";
}

sub something {
    open ( my $foo, '>', '/dev/full' );
    print $foo 'bar';
}

print "pre\n";
something();
print "post\n";

You can, of course, adjust the arguments list to make exit() return a failure code to the OS. Unfortunately, that's not going to get caught as an exception, though.

This leaves some possibilities, although none are spectacular if you were counting on catching the die(). You could certainly set a flag before the exit and have final clean-up triggered by an END block if that flag is set. You could call the cleanup right from there in the destructor and exit from the cleanup code. If there's ever a reason not to leave the program on the full disk error, you could trigger your complaining/cleanup code in there and continue.

Depending on how much state you want to handle, you can work around the die getting caught lots of ways. Here's one that works in toy testing, and lets you use it as a module:

package Foo;
my $error;

END {
    warn $error if $error;
}

sub IO::Handle::DESTROY {
    print "desctructor enter\n";
    my $self = shift;
    close $self || do {
        $error = $!;
        exit;
    };
    print "destructor exit\n";
}

1;

You can make the END block do whatever you need it to do to complain/cleanup. Just put use Foo; at the top of your program, and any failed file close triggers exit and what ever's in your END block. For that matter, since setting IO::Handle::DESTROY in the module seems to work pretty well, you could just put your cleanup code in there, too.