note
eyepopslikeamosquito
<P>
Since I assume you are new to Perl and to programming,
permit me to give you some general advice:
<ul>
<li> Take care with your indenting
<li> In addition to "use warnings", add "use strict"
</ul>
</P>
<P>
Your code could be written more simply like this:
<CODE>
use strict;
use warnings;
print <<'JONAG';
Do you want to print the program's
1. default strings in reverse order
2. or enter your own to be reversed ?
Choose option 1 or 2 or q to quit
JONAG
my $choice = <STDIN>;
chomp $choice;
if ($choice eq 'q') {
print "quitting\n";
exit;
}
# This is the default value.
my @lines = qw( wrda vzc rregr zfgr bzfgzffg rergrge d fgsrg rwer ds vsgsrg );
if ($choice == 2) {
print STDERR "enter your own strings\n";
chomp(@lines = <STDIN>);
}
foreach my $line (reverse @lines) {
print "\t$line\n";
}
</CODE>
</P>
<P>
First notice that I replaced:
<CODE>
print "do you want to print the program's\n", "1. default strings in reverse order\n", "2. or enter your own to be reversed ?\n";
</CODE>
with:
<CODE>
print <<'JONAG';
Do you want to print the program's
1. default strings in reverse order
2. or enter your own to be reversed ?
Choose option 1 or 2 or q to quit
JONAG
</CODE>
which is easier to read and maintain.
This uses a feature of Perl called "here-documents".
See [doc://perlop] (search for <C><<</C> in the "Quote-Like Operators" section).
</P>
<P>
I added the lines:
<CODE>
chomp $choice;
if ($choice eq 'q') {
print "quitting\n";
exit;
}
</CODE>
The chomp is to remove the newline before checking whether <C>$choice</C>
is equal to <C>'q'</C> or not.
Note that I used the "alphabetic" operator <C>eq</C> rather than the
numeric equivalent <C>==</C>.
In Perl, the "alphabetic" version of an operator (in this case <C>eq</C>)
compares the two operands
as if they are strings, while the "punctuation" version (in this case <C>==</C>)
compares them numerically.
For example, <C>"01" eq "1"</C> is false because the strings are of different
length,
while <C>"01" == "1"</C> is true because, numerically, they both evaluate to one.
See [doc://perlop] ("Equality Operators" section) for more information.
</P>
<P>
I set the default value via:
<CODE>
my @lines = qw( wrda vzc rregr zfgr bzfgzffg rergrge d fgsrg rwer ds vsgsrg );
</CODE>
Note the "my" variable declaration, which is required by "use strict".
Variables declared with "my", known as "lexical variables", are known
from the point of declaration to end of scope.
This protects you from many common booboos,
such as mis-spelling a variable name,
and generally makes the code easier to understand and maintain
by explicitly limiting variable scope.
See [doc://strict] for details.
</P>
<P>
Finally, I reorganized the code to remove unnecessary code duplication
(see <a href="http://en.wikipedia.org/wiki/Don't_repeat_yourself">DRY</a>).
That is, the "user entered" data just sets the <C>@lines</C> array. Nothing
more.
That guarantees that the identical code is used for both the default case
and the user-entered case.
Your original code had slightly different code for the two cases.
Also, your code was needlessly altering the array.
For example, instead of your:
<CODE>
foreach $line (@proglines) {
$line = "\t$line";
$line .= "\n";
}
print "@proglines";
</CODE>
which needlessly changes the <C>@proglines</C> array, you can simply
print the formatted lines without changing the <C>@proglines</C> array like so:
<CODE>
foreach my $line (@proglines) {
print "\t$line\n";
}
</CODE>
or even:
<CODE>
print map { "\t$_\n" } @proglines;
</CODE>
if you want to get fancy.
</P>
<P>
<B>Update:</B> as for why you should use strict, I found these nodes:
<ul>
<li> [id://87956] (earlier version: [id://87628])
<li> [id://111088]
<li> [id://952446]
</ul>
</P>
<P>
<ul>
<li> [id://115515]
<li> [id://405770]
<li> [id://482733]
<li> [id://37204]
<li> [id://686571]
</ul>
</P>
1004376
1004376