note
tye
<p>
You don't need a stream; you want an iterator (yes, similar term). To turn this into an iterator in Perl5, you need to keep your own "stack". That is easy to do with an anonymous array (or two) inside your object.
</p><p>
I put file names that I have yet to output into <code>@{ $self->{files} }</code> and output the next one from there the next time the iterator is called. I put directory names that I have yet to read the list of files from into <code>@{ $self->{dirs} }</code> and when there aren't any more file names to return, I read the next directory.
</p><p>
First, here is how you'd use my iterator:
</p><code>
#!/usr/bin/perl
use strict;
use warnings;
require List;
my $f= List->new( @ARGV );
my $file;
while( $file= $f->next() ) {
print "$file\n";
}
</code><p>
And here is the code that implements it:
</p><code>
package List; # Terrible name
use strict;
use warnings;
use Cwd qw( cwd );
require File::Spec;
use vars qw( $VERSION );
$VERSION = '0.99';
sub new {
my( $class, $path )= @_;
my $self= { };
if( defined $path ) {
$self->look_in( $path );
}
bless $self, $class;
return $self;
}
sub look_in {
my( $self, $path )= @_;
$path= cwd() unless @_ > 1;
$path= File::Spec->canonpath($path);
$self->{path}= $path;
$self->{dirs}= [$path];
$self->{files}= [];
}
sub next {
my( $self )= @_;
while( 1 ) {
if( @{ $self->{files} } ) {
my $file = shift @{ $self->{files} };
if( -d $file ) {
push @{ $self->{dirs} }, $file;
}
return $file;
}
if( ! @{ $self->{dirs} } ) {
return;
}
my $dir= shift @{ $self->{dirs} };
if( opendir( DIR, $dir ) ) {
$self->{files}= [
map {
File::Spec->catfile( $dir, $_ );
} File::Spec->no_upwards( readdir(DIR) )
];
closedir DIR;
} else {
warn "opendir failed, $dir: $!\n";
}
}
}
1;
</code><p>
I tested it enough to see that it appears to work just fine.
</p><p>
If you had directories with huge numbers of files directly in them (not in subdirectories), then you might want to make the iterator a bit more complicated such that you don't keep a list of file names and instead return each file name (almost) immediately after you get it back from [readdir] (but I'm not sure I would recommend that).
</p>
<div class="pmsig"><div class="pmsig-22609"><p align="right">
- [tye]<tt> </tt>
</p></div></div>
349582
349582