perlmeditation
brian_d_foy
<p>
Randal has been playing around with Aperture to organize his photos on his MacBook then upload them to Flickr. It has a nifty feature to geotag images based on the current view in Google Earth.
</p>
<p>
I figured that must be using AppleScript, so I tried creating a [cpan://Mac::Glue] glue for it:
</p>
<code>
% sudo gluemac /Applications/Google\ Earth.app
</code>
<p>
That worked. The glue isn't that interesting. I can get the data for the current view, which is what Aperture does:
</p>
<code>
my $gEarth = Mac::Glue->new('Google_Earth');
my $reco = $gEarth->getviewinfo;
</code>
<p>
That gives me a hash:
</p>
<code>
{
'azimuth' => '1.19852752792094e-14',
'longitude' => '-96.4999988896226',
'distance' => '25484000',
'latitude' => '40.4999984526947',
'tilt' => '-1.26725225589562e-15'
}
</code>
<p>
I want to set the view though. But what to set it too? How about flying through all of the Perl Mongers locations? I can get those from the <a href="http://www.pm.org/groups/perl_mongers.xml">Perl Mongers XML file</a>. Once I extract the latitude and longitude I pass it back to <code>setviewinfo</code>. If I wanted to get really fancy I could then use <code>savescreenshot</code> to save the view.
</p>
<code>
#!/usr/bin/perl
use LWP::Simple;
use Mac::Glue;
print "Downloading Perl Mongers XML file...";
my $data = get( 'http://www.pm.org/groups/perl_mongers.xml' );
$data ? ( print "done\n" ) : ( die "Could not get file!" );
# See Mac::Glue for details on creating the glue, probably:
# gluemac /Applications/Google\ Earth.app
print "Starting Google Earth...";
my $gEarth = Mac::Glue->new( 'Google_Earth' );
$gEarth ? ( print "done\n" ) : ( die "Could not start Google Earth!" );
while( $data =~ m|<group.*?>(.*?)</group>|gs )
{
# I could use an XML parser, but it's too easy to do it myself
my( $name, $long, $lat ) = $1 =~ m|
<name>(.*?)</name>
.*?
<longitude>(.*?)</longitude>
.*?
<latitude>(.*?)</latitude>
|xs;
print "Flying to $name\n";
$gEarth->setviewinfo(
{
'azimuth' => '0',
'longitude' => $long,
'distance' => '4000',
'latitude' => $lat,
'tilt' => '0'
}
);
sleep 15;
}
</code>
<p>
You might have to make that sleep a little longer if you have a slower network connection, and maybe you want to loop around the <code>setviewinfo</code> to start farther up (that number is in meters) and zoom in.
</p>
<p>
Have fun :)
</p>
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-366986">
-- <br />
brian d foy <brian@stonehenge.com><br />
Subscribe to <a href="http://www.theperlreview.com">The Perl Review</a>
</div></div>