note
brian_d_foy
<p>
You're really asking how to write accessor methods. You call a method and you get the value of some property. You want to write methods that ask the question you want answered.
</p>
<p>
Here are two class, <code>Parent</code> and <code>Child</code>. The <code>Child</code> class inherits from <code>Parent</code>. Inside each class there is a <code>VERSION</code> method that returns the value of the <code>$VERSION</code> in that package. In neither case is <code>$VERSION</code> part of the object. They are class data.
</p>
<code>
package Parent;
our $VERSION = 1.23;
sub VERSION { $VERSION }
sub child_version { $_[0]->VERSION }
package Child;
use base qw(Parent);
our $VERSION = 5.43;
sub VERSION { $VERSION }
sub new { bless {}, $_[0]; }
sub parent_version { $_[0]->SUPER::VERSION }
</code>
<p>
Those <code>VERSION</code> methods take care of answering the version question for each package as long as I call them directly as class methods:
</p>
<code>
print "Parent version is ", Parent->VERSION, "\n"; # 1.23
print "Child version is ", Child->VERSION, "\n"; # 5.43
</code>
<p>
But now I want to do that from a <code>Child</code> object. That's where the <code>child_version</code> and <code>parent_version</code> methods come in. Once I have the <code>$child</code> object, in <code>parent_version</code> I can get its parent version by calling its <code>SUPER</code> class. The <code>SUPER</code> is a virtual class that is the parent class of the one it is compiled in (<code>Child</code> in this case).
</p>
<code>
my $child = Child->new;
print "Child version: ", $child->VERSION, "\n"; # 5.43
print "Parent version: ", $child->parent_version, "\n"; # 1.23
</code>
<p>
The <code>VERSION</code> and <code>parent_version</code> methods in <code>Child</code> take care of most everything you need. Where you're getting confused, I think, is how the <code>Parent</code> fits in to this. More on that in a moment. You can add a <code>child_version</code> method to <code>Parent</code>. It just takes the first thing on the argument list and calls <code>VERSION</code> on it. When I call <code>child_version</code> on the <code>$child</code> object, Perl doesn't find the <code>child_version</code> in <code>Child</code> so it looks in its superclass and finds it in <code>Parent</code>:
</p>
<code>
print "Child version: ", $child->child_version, "\n"; # 5.43
</code>
<p>
However, one of the points of inheritance is that you shouldn't need this two-way communication. You don't think about the parent class having part of it and the child class having another part. In this case, the <code>child_version</code> method is just the same thing as <code>Child</code>'s <code>VERSION</code>:
</p>
<code>
print "Child version: ", $child->VERSION, "\n"; # 5.43
print "Child version: ", $child->child_version, "\n"; # 5.43
</code>
<p>
In <code>Parent</code>'s <code>child_version</code>, it takes the first thing on the argument list, which is the <code>$child</code> object. That's how <code>Parent</code> accesses anything it needs to know in <code>Child</code>: just ask the child object that you got as the first argument.
</p>
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-366986">
-- <br />
brian d foy <brian@stonehenge.com><br />
Subscribe to <a href="http://www.theperlreview.com">The Perl Review</a>
</div></div>
712303
712303