note
tirwhan
<blockquote><i></i></blockquote>
<p>To further expand on the two (perfectly correct and valid) comments by [almut] and [moritz] above, here is a script that does exactly what you asked for:</p>
<c>
#!/usr/bin/perl
use warnings;
use strict;
use Parallel::ForkManager;
use Sys::CPU;
my $number_of_cpus = Sys::CPU::cpu_count();
my $pm = new Parallel::ForkManager($number_of_cpus);
for (1..$number_of_cpus) {
my $pid = $pm->start and next;
my $string="abcdefg";
my $ln=length($string);
print "length of a string = $ln \n";
$pm->finish();
}
</c>
<p>This uses [mod://Sys::Cpu] to find the number of CPUs the system has, then forks off that number of processes and executes the code in them. Note you'll get the output ("length of a string...") multiple times (depending on the number of processors you have in the system), because exactly the same code is run in each process. So this approach is rather nonsensical, it uses all processors (normally, depends on your OS) but simply multiplies the workload. Something more sensible would be to have each child measure a different string, e.g.:</p>
<c>
#!/usr/bin/perl
use warnings;
use strict;
use Parallel::ForkManager;
use Sys::CPU;
my $number_of_cpus = Sys::CPU::cpu_count();
my $pm = new Parallel::ForkManager($number_of_cpus);
my @strings = ("abcde","abcdefghij","ab");
for (1..scalar @strings) {
my $pid = $pm->start and next;
my $string=$strings[$_-1];
my $ln=length($string);
print "length of string \"$string\" = $ln \n";
$pm->finish();
}
</c>
<p>This will hand each child a different string and thus "parallelize" the work done. This is slightly less senseless than the previous example, but only slightly, because the work done by your machine to fork off a separate process is much more than the simple act of measuring the length of a string. So, as the previous commenters have already pointed out, you need to do some thinking on exactly what you want to parallelize and how to do it in a worthwhile fashion. Anyway, hope this helps clear up some confusion.</p>
<div class="pmsig"><div class="pmsig-237051">
<br><i>All dogma is stupid.</i>
</div></div>
833215
833215