note
jwkrahn
<blockquote><i><c>
# Scrabble distribution
our %letter_distribution = qw(
a 9 b 2 c 2 d 4
e 12 f 2 g 3 h 2
i 9 j 1 k 1 l 4
m 2 n 6 o 8 p 2
q 1 r 6 s 4 t 6
u 4 v 2 w 2 x 1
y 2 z 1
) ;
</c></i></blockquote>
<p>
You never use this variable anywhere so why is it here?
</p><br /><br />
<blockquote><i><c>
sort { score_word($a) cmp score_word($b) }
</c></i></blockquote>
<p>
<c>score_word()</c> returns a numeric value so that should be:
</p>
<c>
sort { score_word($a) <=> score_word($b) }
</c>
<p>
And if you used a [wp://Schwartzian Transform] you wouldn't have as much overhead on all those subroutine calls.
</p>
<c>
# search for matching words
my @possible_words =
map $_->[ 1 ],
sort { $a->[ 0 ] <=> $b->[ 0 ] }
map length() == length( $word_pattern ) && pattern_word( $word_pattern, $_ ) ? [ score_word( $_ ), $_ ] : (),
@dictionary;
</c><br /><br />
<blockquote><i><c>
sub score_word {
my ($word) = @_ ;
my $points = 0 ;
my @letters = split //, $word ;
$points += $letter_points{$_} foreach @letters ;
return $points ;
}
</c></i></blockquote>
<p>
You could use [mod://List::Util]::sum and reduce that to:
</p>
<c>
use List::Util qw/ sum /;
sub score_word { sum( @letter_points{ split //, $_[ 0 ] } ) }
</c><br /><br />
<blockquote><i><c>
my %deny_letters = map { $_ => 1 } split(//, $pattern) ;
my @p = split //, $pattern ;
</c></i></blockquote>
<p>
Why [doc://split] the same thing twice:
</p>
<c>
my @p = split //, $pattern ;
my %deny_letters = map { $_ => 1 } @p ;
</c>
927629
927629