note
tobyink
<p>Yes. The basic technique is to create a new package which inherits from the old one but adds some new methods, then rebless the object into that new package. Here's a quick example:</p>
<code>
use 5.010;
use Math::BigInt;
# quite big!!
my $seven = Math::BigInt->new('7');
# $seven cannot "speak", so this warns
eval { $seven->speak } or warn $@;
{
package Math::BigInt::Speaker;
our @ISA = qw(Math::BigInt);
use Scalar::Util qw(blessed);
use Carp qw(confess);
sub upgrade {
my ($class, $instance) = @_;
confess "can only upgrade Math::BigInt objects"
unless blessed $instance && $instance->isa('Math::BigInt');
bless $instance => $class;
}
sub speak {
CORE::say($_[0]);
}
}
# Swaps $seven into our new class.
Math::BigInt::Speaker->upgrade($seven);
# $seven can now "speak"
eval { $seven->speak } or warn $@;
</code>
<p>If you use [mod://Moose] you can do this in a much nicer and more organised way. (Though it's basically the same thing happening under the hood.) You'd just create a new anonymous role, and apply that role to the object.</p>
<code>
use 5.010;
use Math::BigInt;
use Moose ();
# quite big!!
my $seven = Math::BigInt->new('7');
# $seven cannot "speak", so this warns
eval { $seven->speak } or warn $@;
my $speaker = Moose::Meta::Role->create_anon_role(
methods => {
speak => sub { CORE::say($_[0]) },
},
);
Moose::Util::apply_all_roles($seven, $speaker);
# $seven can now "speak"
eval { $seven->speak } or warn $@;
</code>
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-757127">
<small><small>
<tt>perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'
</tt></small></small>
</div></div>
996022
996022