Re^2: sort hash of arrays of arrays

[maladav]

in reply to Re: sort hash of arrays of arrays
in thread sort hash of arrays of arrays

Ok, sorry, it's not a multi-dimensional array this way. In my script I build it up from a tab-delimited text file as follows:

my %hash;

while (<FILE>) {

chomp;
my @line = split("\t");
push(@{$hash{$line[1]}}, [@line]);

}

This, at the end, is a 3-D array.
How can I do the sort based on the 2nd item of the innermost array?

Thank you,
maladav

[BrowserUk]

How can I do the sort based on the 2nd item of the innermost array?

Okay. So you have a hash of arrays of arrays; something like this:

{
  1 => [
    [1, 2, 3], 
    [6, 7, 8], 
    [16, 17, 18], 
    [26, 27, 28]
  ],
  2 => [
    [2, 3, 4], 
    [7, 8, 9], 
    [17, 18, 19], 
    [27, 28, 29]
  ],
  3 => [
    [3, 4, 5], 
    [8, 9, 10], 
    [18, 19, 20], 
    [28, 29, 30]
  ],
  4 => [
    [4, 5, 6], 
    [9, 10, 11], 
    [19, 20, 21], 
    [29, 30, 31]
  ],
}

The second item of which innermost array?

Each outer array contains multiple arrays. Which of those do you which to sort on? The first? The last? All of them?

[maladav]

I'd like to sort the outer arrays of each hash item (1-4) separately, based on the second item of the inner arrays to finally have something like:

{
  1 => [
    [26, 27, 28],
    [16, 17, 18],
    [6, 7, 8],
    [1, 2, 3]
  ],
  2 => [
    [27, 28, 29],
    [17, 18, 19],
    [7, 8, 9],
    [2, 3, 4],
  ],
  3 => [
    [28, 29, 30],
    [18, 19, 20],
    [8, 9, 10],
    [3, 4, 5]
  ],
  4 => [
    [29, 30, 31],
    [19, 20, 21],
    [9, 10, 11],
    [4, 5, 6]
  ],
}

So for the first set, values 2, 7, 17 and 27 were compared to get the right order.
I hope this clarifies my problem.

Thanks

[BrowserUk]

Then you need to do one sort for each key in the hash like this:

@{ $hash{$_} } = sort{ $b->[1] <=> $a->[1] } @{ $hash{$_} } for keys %
+hash;;

pp \%hash;;
{
  1 => [[26, 27, 28], [16, 17, 18], [6, 7, 8], [1, 2, 3]],
  2 => [[27, 28, 29], [17, 18, 19], [7, 8, 9], [2, 3, 4]],
  3 => [[28, 29, 30], [18, 19, 20], [8, 9, 10], [3, 4, 5]],
  4 => [[29, 30, 31], [19, 20, 21], [9, 10, 11], [4, 5, 6]],
}