use strict;
use warnings;

use Scalar::Util qw( looks_like_number );
use IO::Prompt::Hooked;

my %rates = (
  'pounds'        => 1,
  'usd'           => 1.6,
  'marks'         => 3.0,
  'french francs' => 10.0,
  'yen'           => 174.8,
  'swiss francs'  => 2.43,
  'drachma'       => 492.3,
  'euro'          => 1.5
);


my ($from, $to) = get_targets(\%rates);

my $value = get_value();

my $converted = $value * ($rates{$to} / $rates{$from});
printf "$value $from is %.2f $to.\n", $converted;


# Manage prompting for "from" and "to" currencies.
sub get_targets {
  my $currencies = shift;
  return
    map { get_currency($_, $currencies) }
    ('Enter your starting currency:', 'Enter your target currency:');
}

# Prompt for an individual currency.  5 tries.  Die if we don't get
# good input.
sub get_currency {
  my ($msg, $curr) = @_;
  my $in = prompt(
    message  => $msg,
    tries    => 5,
    validate => sub { return exists $curr->{lc shift}; },
    error    => sub {
      my $valid = join ', ', keys %{$curr};
      return "Currency must be one of the following: ($valid).\n"
        . "$_[1] tries remaining.\n";
    },
  );
  die 'Too many tries. Consult someone who can read.' unless defined $in;
  return lc $in;
}

# Prompt for a value to convert.  Die if we don't get good input after
# five tries.
sub get_value {
  my $input = prompt(
    message  => "Enter an amount to convert:",
    default  => 0,
    tries    => 5,
    validate => sub { return looks_like_number shift; },
    error    => sub {
      return "Amount must be a number.  $_[1] tries remaining.\n";
    },
  );
  die "Unable to obtain a valid value for conversion." unless defined $input;
  return $input;
}