Here is one way:

#! perl
use Modern::Perl;
use List::Util qw( min );

my @vals  = qw(   5   3   2  12   2 );
my @names = qw( Cat Bat Cow Dog Rat );

my $min_val = min @vals;
my @indices = grep { $vals[$_] == $min_val } (0 .. $#vals);

for (@indices)
{
    printf "Lowest value: %d, index: %d, corresponding name: %s\n",
            $min_val, $_, $names[$_];
}
[download]

Output:

18:01 >perl 429_SoPW.pl
Lowest value: 2, index: 2, corresponding name: Cow
Lowest value: 2, index: 4, corresponding name: Rat

18:03 >
[download]

Hope that helps,

Hi Athanasius,

Thanks for your quick reply. Your code has worked nicely. It has solved my problem.

Regards,

This could probably be refactored more elegantly, but it seems to do the job in a single pass without undue complexity.

use strict;
use warnings;

my @values = qw( 5 3 2 12 2 );
my @names  = qw( Cat Bat Cow Dog Rat );

my $min;
my @indices;

foreach my $ix ( 0 .. $#values ) {
  if( ! defined $min or $values[$ix] < $min ) {
    @indices = ($ix);
    $min = $values[$ix];
  }
  elsif( $min == $values[$ix] ) {
    push @indices, $ix;
  }
}

print "Lowest value: $min\n";
print "$_ => $names[$_]\n" for @indices;
[download]

Hi Dave,

Thanks for your prompt reply. Your code is simple for me to understand. It has solved my problem.

With regards,

This node was taken out by the NodeReaper on Dec 13, 2012 at 13:52 UTC
Reason: [Lotus1]: duplicate node

You may view the original node and the consideration vote tally.

Here's another option:

use Modern::Perl;

my @values = qw/5 3 2 12 2/;
my @names  = qw/Cat Bat Cow Dog Rat/;
my %hash;

push @{ $hash{ $values[$_] } }, $_ for 0 .. $#values;

my $lowest = ( sort { $a <=> $b } keys %hash )[0];

say "Positions of Lowest Value ($lowest) = @{$hash{$lowest}}";
print 'The animal names are: ';
print join ' ', map $names[$_], @{$hash{$lowest}};
[download]

Output:

Positions of Lowest Value (2) = 2 4
The animal names are: Cow Rat
[download]

Hi Kenosis,

Thank you very much for your prompt reply and the code. It has worked well and has solved my problem.

With Regards,

Trying to maintain parallel arrays in that fashion if fraught with peril. Instead use a data structure where you can treat each data pair as an entity. One way to do that would be to use OO and generate an object for each animal. For the current sample a simple hash will suffice. Consider:

use strict;
use warnings;

my %animals = (
    Cat => 5,
    Bat => 3,
    Cow => 2,
    Dog => 12,
    Rat => 2
);
my %byValue;

push @{$byValue{$animals{$_}}}, $_ for keys %animals;

my @ordered = sort {$a <=> $b} keys %byValue;

print "$_: @{$byValue{$_}}\n" for @ordered;
[download]

Prints:

2: Rat Cow
3: Bat
5: Cat
12: Dog
[download]

Note the use of the reverse lookup hash byValue to ease accessing the animals in sorted order.

Hi GrandFather,

Thanks for your code.

With kind regards,

"Lowest value" is singular, but your narrative and requirements treat it as if it meant "the two lowest values (plural)."

So why not "three lowest"? ... or "four?"

P.S added:

And how if understanding a hash is "a little complicated to me" how did you manage to write

011: @array_element_pos{@values}=(0..$#values);
012: $i=$array_element_pos{$min};

You seem to be stuck at the same old stand (Re: How can one create a folder B in D drive and save results in a text file inside B using perl script?) -- presenting incoherent questions and, when you include code, doing so with samples that appear to be beyond your competence, cargo-culted in bits and pieces, or un-compilable.

Please, do yourself (and us) a favor, and get the basics right (yes, hashes are among those basics). You'll find that further learning comes easier.

Homework! =)