Test::$pkg::hello($pkg);
[download]

    {
        no strict 'refs';
        &{"Test::" . $pkg. "::hello"}($pkg);
    }
[download]

The following works with strict on:

(\&{"Test::${pkg}::hello"})->($pkg);
[download]

The same, but more readable:

my $sub = \&{"Test::${pkg}::hello"};
$sub->($pkg);
[download]

Then again, explicitly using no strict 'refs'; might be better a good thing.

That said, it looks like you have a method call (to which you're passing the wrong package name). If so, you should be using

("Test::".$pkg)->hello(...);
[download]

A package is just a namespace identified by a string.

package Test::One;

sub hello{
    my $var = shift;
    print "Hello: $var\n";
}

1;

package Test::Two;

sub hello{
    my $var = shift;
    print "Hello: $var\n";
}

1;

package main;

use strict;
use warnings;
use Data::Dumper;

my @pkgs = qw( One Two );

foreach my $pkg ( @pkgs ) {
    "Test::$pkg"->hello();
}
[download]

This is one step toward full-fledged classes and objects, which may be a better solution in the longrun: perlobj.

If you can't plan on passing the package name as the first parameter (which is what the Class->method() notation does), then you have to construct the fully qualified sub name, which means symbolic references and some ugly syntax:

foreach my $pkg ( @pkgs ) {
    no strict 'refs';
    &{'Test::' . $pkg . '::hello'}($pkg);
}
[download]

Update: Good job on figuring out the symbolic ref syntax on your own. Looks like we both came up with the same.

An alternative to no strict 'refs' would be:

foreach my $pkg ( @pkgs ) {
   my $hello = "Test::$pkg"->can('hello');
   $hello->() if $hello;
}
[download]

... because can returns a coderef. In the case of packages that have inheritance (@ISA) this will act slightly differently to &{'Test::' . $pkg . '::hello'}().

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

can should be used for methods and only for methods, so that should be

my $full_pkg = "Test::".$pkg;
my $hello = $full_pkg->can('hello');
$full_pkg->$hello(...);
# Or: $hello->($full_pkg, ...);
[download]

which simplifies to:

my $full_pkg = "Test::".$pkg;
$full_pkg->hello(...);
[download]

You don't even need can if the method name is variable.

$full_pkg->$method_name(...);
[download]