You are not calling your anonymous subs as methods, thus they don't get any invocant ($self). You could call them like this:

my $method = $a->answers->{answers_comments};
$a->answers->$method(
   123,
   134,
   145,
   { 
      order => "desc",
      sort  => "votes",
   },
);
[download]

Then they'll have an invocant.

It would be much saner though to install your methods as genuine methods, not coderefs floating around attached to blessed objects.

# in Answers.pm
use Sub::Name 'subname';
*answers_comments = subname(
   "Net::StackExchange::V2::Answer::answers_comments",
   one_param("answers","comments"),
);
[download]

Now you can call it like a proper method:

$a->answers->answers_comments(
   123,
   134,
   145,
   { 
      order => "desc",
      sort  => "votes",
   },
);
[download]

Thanks a ton for your reply

.Yep. This is the sorcery I was looking for.

Is this from the Sub::Name module on cpan? It's not part of perls core modules right?

May I ask, what language construct is this :  *answers_comments ?? A pointer of some sort?

perldata#Typeglobs and Filehandles

Modern Perl also covers all the syntax (nice pdf)

*answer_comments is a glob - basically an entry in Perl's symbol table. It is kind of a bundle which contains sub answer_comments, our $answer_comments, our @answer_comments, our %answer_comments and the answer_comments bareword file handle.

If you assign one glob to another, like *xxx = *yyy, then it makes sub xxx and sub yyy aliases for each other, and our $xxx and our $yyy aliases for each other, etc.

use 5.010;
use strict;
use warnings;

our ($xxx, $yyy, @xxx, @yyy);
*xxx = *yyy;  # alias

$xxx = 42;
say $yyy;     # says "42"

@xxx = (9,9,9);
say "@yyy";   # says "9 9 9"
[download]

Anyway, that's what happens when you assign one glob to another glob. But you can also assign references to a glob, in which is doesn't alias the whole bundle, but just the relevant slot within the glob. For example:

use 5.010;
use strict;
use warnings;

our ($xxx, $yyy, @xxx, @yyy);
*xxx = \$yyy;  # alias $yyy, but not @yyy

$xxx = 42;
say $yyy;      # says "42"

@xxx = (9,9,9);
say "@yyy";    # says nothing
[download]

And so one_param returns a coderef, and we can assign it to the glob:

*answers_comments = one_param("answers","comments");
[download]

This effectively installs the sub into the package with a given name. Almost as if you'd done:

package ...;
sub answers_comments {
  ...;
}
[download]

(This is what Exporter does internally - that module is not as magic as it seems.)

I say "almost" though. There's one key difference, and that's what the CPAN module Sub::Name takes care of. When the answers_comments method is called, Perl still internally treats it as an anonymous coderef. Which means that stack traces (e.g. Carp) would show it as "__ANON__" rather than "answers_comments".

Naming the sub is also important if you use something like namespace::autoclean which deletes subs it finds in your package that don't look like methods. Naming a sub makes it look like a method.

So Sub::Name is well worth using when you muck around with globs; it's a shame it's not bundled with Perl.

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

Here is a (hopefully) more obvious interface (and a simpler implementation)

package main;
use strict;
use v5.10;

my $obj = My::StackExchange->new;
my $uri;

$uri = $obj->build_uri(
    type => 'answers',
    ids  => [123,134,145],
    comments => 1,
    options => { 
        order => "desc",
        sort  => "votes"
    }
);
say $uri;

$uri = $obj->build_uri(
    type => 'answers',
    options => { 
        order => "desc",
        sort  => "votes"
    }
);
say $uri;

package My::StackExchange;

use URI::FromHash qw( uri );

sub new { bless {} }

sub build_uri {
    my ($self, %arg) = @_;

    #TODO validate input

    my @paths = ($arg{type});

    if ( $arg{ids} ) {
        push @paths, join(';', @{ $arg{ids} });
    }

    if ( $arg{comments} ) {
        push @paths, 'comments';
    }

    return uri(
        scheme => 'http',
        host => 'api.stackexchange.com',
        path => \@paths,
        query => $arg{options},
    );
}
__DATA__

http://api.stackexchange.com/answers/123;134;145/comments?sort=votes;o
+rder=desc
http://api.stackexchange.com/answers?sort=votes;order=desc
[download]

Thanks for your reply. I see. Yours is an interesting abstraction.

Also, there are urls like this: "/answers/{ids}/comments" where it returns comments on the answers returned by ids. So then I'd have to introduce another parameter or type for it.

Also, there are urls like this: "/answers/{ids}/comments" ...

But isn't that the same as the first example above that returns

http://api.stackexchange.com/answers/123;134;145/comments?sort=votes;o
+rder=desc
[download]

minus the query parameters? The code example I gave already handles that case.

Much saner. :)

- tye