Adding an new element to array.

[Anonymous Monk]

I am trying to add one element "DOC => 'EMAIl'" from $VAR2 to $VAR1,

$VAR1 = {
          'DATE' => '2013-04-25',
          'TW' => '1',
          'REF' => '1234567',
          'ACC' => '33456790'
        };
$VAR2 = {
          'DOC' => 'EMAIL'
        };

but I am stuck, I tried this:

push @$data, {DOC => 'EMAIL'};

No success.

I would like to have this at the end:

$VAR1 = {
          'DATE' => '2013-04-25',
          'TW' => '1',
          'REF' => '1234567',
          'ACC' => '33456790'
          'DOC' => 'EMAIL'
        };

Thanks for the help!

[toolic]

You have a reference to a hash, and you just want to add a new key to the hash:

use warnings;
use strict;
use Data::Dumper;

$Data::Dumper::Sortkeys=1;

my $data = {
          'DATE' => '2013-04-25',
          'TW' => '1',
          'REF' => '1234567',
          'ACC' => '33456790'
        };

$data->{DOC} = 'EMAIL';
print Dumper($data);

__END__

$VAR1 = {
          'ACC' => '33456790',
          'DATE' => '2013-04-25',
          'DOC' => 'EMAIL',
          'REF' => '1234567',
          'TW' => '1'
        };

• perldsc
• perlreftut

[Anonymous Monk]

The data is a array of hashes:

my @new;
foreach my $row (@$data) {

      push @new, DOC => "EMAIL"}; # 
       
     }
push @$data, @$new;

[marinersk]

Adding an new element to array

Just so you know, this is not an array. It is a hash.

Worse, it is a reference to a hash, not a directly specified hash the way most people start using them.

Looks like others are giving guidance on how you might update that hash, so I won't replicate that information here. But nobody seems to have mentioned that you appear to be starting from a faulty assumption: You do not have an array in the usual Perl sense of the word.

[hdb]

How about:

@$VAR1{ keys %$VAR2 } = values %$VAR2;

or just

$VAR1->{'DOC'} = $VAR2->{'DOC'};

[protist]

Here is one good way to do it, but as always, tim toady.

use warnings;
use strict;
use Data::Dumper;

$Data::Dumper::Sortkeys=1;

my $data = {
          'DATE' => '2013-04-25',
          'TW' => '1',
          'REF' => '1234567',
          'ACC' => '33456790'
        };

$data = {%$data, DOC => 'EMAIL'};

print Dumper($data);

Alternatively, to add the second hash to the first, do something like this:

use warnings;
use strict;
use Data::Dumper;

$Data::Dumper::Sortkeys=1;

my $data = {
          'DATE' => '2013-04-25',
          'TW' => '1',
          'REF' => '1234567',
          'ACC' => '33456790'
        };
my $new = {
          DOC => 'EMAIL' ## NOTE: no need for quotes on thing
                         ##       to the left of `=>'
        };

$data = {%$data, %$new};

print Dumper($data);

[Anonymous Monk]

OK may be I am not been clear but this is the reason:

my $data = $dbh->exec("select * ......");

if($data) {

   my $more_data = $dbh ->exec("select * ....");

   if($more_data) {
     my $name = $more_data->[0]{ NAME };
     push @{$data}, {doc_type => $name};
   }

}

print Dumper(@$data);

Thanks!

[poj]

#!perl
use strict;
use Data::Dump 'pp';
my $data = [{ 'DATE' => '2013-04-25',
  'TW'  => '1','REF' => '1234567',
  'ACC' => '33456790' }];
          
my $more_data = [{'DOC1' => 'EMAIL1','DOC2' => 'EMAIL2'}];
my @keys = keys %{$more_data->[0]};
@{$data->[0]}{@keys} = @{$more_data->[0]}{@keys};
pp @$data;

poj