Passing a string to call an array?

[pzj20012]

#!/usr/bin/perl
use strict;
use warnings;
use List::Util qw(min max);

my @HD = (0.153488905,    0.153488905,    3.688879454);
my $testing = "HD";
print @($testing); #this does not work.

Is there anyway to pass the 'string' in $testing as the array name to call out the array?

[GrandFather]

Why? With the trivial sample code you've shown there is no compelling reason to do that.

In some cases it may be appropriate to use a hash of arrays and use 'HD' as a key to access the specific HD array. Consider:

my %arrays = (HD => [0.153488905, 0.153488905, 3.688879454]);
my $testing = "HD";

print "@{$arrays{$testing}}";

prints:

0.153488905 0.153488905 3.688879454

[pzj20012]

thank you!

[Athanasius]

Hello pzj20012, and welcome to the Monastery!

See also the Perl documentation FAQ How can I use a variable as a variable name? to see how to do this, and (far more importantly) why you shouldn’t!

Hope that helps,

[Laurent_R]

What you are trying to do is called a symbolic reference and (1) it is forbidden under the use strict; pragma, and (2) it can't be done with lexical variables. And, in general, it should not be done either, using a hash or a hash of arrays as suggested above (or a hash of hashes, as the case may be) is almost always a much better idea.

[AnomalousMonk]

In the spirit of offering good advice and then immediately undermining it, here's a way to do exactly what you asked about in your OP.

As already mentioned, symbolic referencing does not work with lexical (i.e., my) variables, but only with package (i.e., global) variables. Thus, the  my @HD = ... ; statement of the OPed code becomes the  our @HD = ... ; statement below (see our) pre-declaring and initializing the  @HD array package variable. Pre-declaration of variables is one of the practices imposed by strict. Use of strict (and warnings) is highly recommended, especially for novice Perlers, so keep doing this.

Another restriction imposed by strict is that symbolic referencing is right out, so you have to turn off this particular stricture (i.e., 'refs'; see no) before using a symbolic reference. Strictures are lexical in scope, so turn off this restriction in the narrowest possible scope, leaving it in force in the rest of your code.

The other good point already made is that symbolic referencing is almost never needed. Dominus's Why it's stupid to `use a variable as a variable name' is another good discussion of the reasons why.

So at last, after all the good advice not to play with fireworks, here's a bunch of 'crackers and a box of matches and the stern admonition not to come crying to me if you lose a couple of fingers.

>perl -le
"use warnings;
 use strict;
 ;;
 our @HD = (0.153488905, 0.153488905, 3.688879454);
 my $testing = 'HD';
 { no strict 'refs';
   print @{$testing};
   print qq{x @{$testing} y};
   }
"
0.1534889050.1534889053.688879454
x 0.153488905 0.153488905 3.688879454 y

[Laurent_R]

Thank you, AnomalousMonk, I actually wanted to refer the OP to exactly the same three pages from Mark Jason Dominus, but did not find the right syntax to create the link correctly.