Inplace Editing

[tachyon]

Description:

This comes up so often I thought it deserved a snippet. This code will read all the files in a directory and then inplace edit them acording to a regex. A backup of the original file with the extension .bak is created.

#!/usr/bin/perl -i.bak -w

# inplace.pl A short program to edit all the files in a dir inplace

use strict;

my $dir = 'c:/test1';
my @files;

opendir(DIR, $dir) or die "Can't open dir $dir, Perl says $!\n";
while (my $file = readdir DIR) {
    # only push in the files not the dirs - use full path!
    push @files, "$dir/$file" unless -d "$dir/$file";
}
closedir DIR;

# now do an inplace edit. use a bare block and local to limit
# the scope of our changes to the global @ARGV array to just here
{
    local @ARGV = @files;   # set up a temporary @ARGV for in-place ed
+it
    while (<>) {
        s/this/that/;       # modify the file
        print;              # print the modifications
    }
}

[rob_au]

From the first Camel book, page 253, "Substituting strings in many files":
 


perl -pi.bak -e 's/OLDSTRING/NEWSTRING/g' FILELIST


 

 
Ooohhh, Rob no beer function well without!

[clemburg]

Unfortunately, on Win32 platforms the shell does not expand wildcards in FILELIST like on Unix platforms, therefore you need to use something like this there:

> perl -MFile::DosGlob -i.bak -pe "BEGIN {@ARGV=glob(join ' ', @ARGV)}
+ s/foo/bar/g" *.txt *.bak

Christian Lemburg
Brainbench MVP for Perl
http://www.brainbench.com

[$code or die]

if the script is not run with -i, you can do this:

{
    local ($^I, @ARGV) = ('.bak', @files);   
    while (<>) {
        s/this/that/;
        print;       
    }
}

It's also useful if you ARE running with -i and wish to use a different extension for the backup file.

Error: Keyboard not attached. Press F1 to continue.

[WAP_happens]

On the principle that shorter is better I do it like this:

perl -p -i -n -e 's/this/that/g' *.txt

BTW when I use -pine for the switches it doesn't work, anyone know why?

[Hofmator]

Know your command line switches ;-) ... two things

• -p and -n contradict each other (and actually p overrides n).
• -pine switches on the p switch and uses backup files which append ne to the filename - so my suggestion is -pi -e.

-- Hofmator