How can I split a string into chunks of 4 characters

PetreAdi has asked for the wisdom of the Perl Monks concerning the following question:

Replies are listed 'Best First'.

Re: How can I split a string into chunks of 4 characters
by Athanasius (Archbishop) on Dec 06, 2013 at 16:31 UTC

Use a positive look-ahead assertion, like so:

 2:28 >perl -MData::Dump -we "my $s = '01234abc'; my @a = $s =~ /(?=(.
+{4}))/g; dd @a;"
("0123", 1234, "234a", "34ab", "4abc")

 2:29 >
[download]

Hope that helps,

Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

[reply]
[d/l]

Re: How can I split a string into chunks of 4 characters
by davido (Cardinal) on Dec 06, 2013 at 16:54 UTC

my @array = map {  substr $string, $_, 4  }  0  ..  length( $string ) 
+- 4;
[download]

If the string is really long, use a $position variable and a while loop so that internally the big 0 .. length( $string ) - 4 list doesn't need to be built and stored:

my $pos = 0;
while( $pos <= length( $string ) - 4 ) {
  push @array, substr( $string, $pos++, 4 );
}
[download]

Dave

[reply]
[d/l]
[select]

Re: How can I split a string into chunks of 4 characters
by BrowserUk (Patriarch) on Dec 06, 2013 at 21:26 UTC

$str = '0123456789abcdef';;

print for unpack '(a4X3)' . (length($str)-3), $str;;
0123
1234
2345
3456
4567
5678
6789
789a
89ab
9abc
abcd
bcde
cdef
[download]

With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

[reply]
[d/l]

Re: How can I split a string into chunks of 4 characters
by Random_Walk (Prior) on Dec 06, 2013 at 16:31 UTC

use strict;
use warnings;
use 5.010;

my $len    = 4;
my $string = "01234abc";

for (0 .. (length $string - $len) ) {
    say substr $string, $_, $len;
}

# or in an array
my @chunks = map {substr $string, $_, $len} (0 .. (length $string - $l
+en) );
say join "<>", @chunks;
[download]

Cheers,
R.

Pereant, qui ante nos nostra dixerunt!

[reply]
[d/l]

Re: How can I split a string into chunks of 4 characters
by oiskuu (Hermit) on Dec 07, 2013 at 12:01 UTC

length($string) >= 3

  @array = unpack 'x*X3 .@0/(a4X3)', $string;
[download]

Athanasius's solution

  @array = $string =~ m/(?=(.{4}))/g;
[download]

[reply]
[d/l]
[select]

Re: How can I split a string into chunks of 4 characters
by kcott (Archbishop) on Dec 07, 2013 at 14:35 UTC

G'day PetreAdi,

Here's another way to do it.

#!/usr/bin/env perl -l

use strict;
use warnings;

my $string = '01234abc';
my @chars = split // => $string;
my @chunks; 
push @chunks, join '' => @chars[$_ .. $_ + 3] for 0 .. length($string)
+ - 4;
print "@chunks";
[download]

Output:

0123 1234 234a 34ab 4abc
[download]

-- Ken

[reply]
[d/l]
[select]

Re: How can I split a string into chunks of 4 characters
by Lennotoecom (Pilgrim) on Dec 06, 2013 at 18:06 UTC

$_ = '01234567890'; push @a, $1 while s/(.{1,4})//;
[download]

$_ = '01234abc';

$_ = $2.$', push @a, $& while /(.)(.{3})/;
[download]

[reply]
[d/l]
[select]

Re^2: How can I split a string into chunks of 4 characters

by davido (Cardinal) on Dec 06, 2013 at 20:27 UTC

"push @a, $1 while s/(.{1,4})//;" produces the following: "0123 4abc", which is not the desired result.

Dave

[reply]
[d/l]
[select]

Re^3: How can I split a string into chunks of 4 characters

by Lennotoecom (Pilgrim) on Dec 06, 2013 at 21:36 UTC

i will cite the author
"For example, string "01234abc" would become array 0123 4abc"
it is exactly what my script does
you sir, I suppose, didn't read the task

[reply]

Re^4: How can I split a string into chunks of 4 characters

by AnomalousMonk (Archbishop) on Dec 06, 2013 at 22:15 UTC


Don't ask to ask, just ask
	PerlMonks