Re: Not sure how to populate a hash

[LanX]

you could use a hash slice to populate many slots at once

@$hashref{@keys}=@values

With

$hashref=$nodemetrics{$node}

update

Not sure why you prepopulate to 0, simply undef seems more robust and is easily done:

@$hashref{@keys}=()

HTH :)

[aditya1977]

Sorry Rolf

I'm afraid I still dont get it. :-(

By @keys do you mean @system_attributes?

So I need to do this?

@$hashref{@system_attributes}=@data;

[Athanasius]

Hello aditya1977,

In the spirit of TMTOWTDI, here’s a concise implementation of LanX’s hash slice solution:

#! perl
use strict;
use warnings;
use Data::Dump;

my %nodemetrics;
my @nodelist   =  qw(server1 server2);
my @attributes =  qw(memory cpu disk network);
my $string     = '1024|2200|30|100';
my @data       =  split /\|/, $string;

@{  $nodemetrics{$_     } }{@attributes} = (0) x @attributes for @node
+list;
dd \%nodemetrics;
@{  $nodemetrics{server1} }{@attributes} = @data;
dd \%nodemetrics;

Output:

22:03 >perl 1027_SoPW.pl
{
  server1 => { cpu => 0, disk => 0, memory => 0, network => 0 },
  server2 => { cpu => 0, disk => 0, memory => 0, network => 0 },
}
{
  server1 => { cpu => 2200, disk => 30, memory => 1024, network => 100
+ },
  server2 => { cpu => 0, disk => 0, memory => 0, network => 0 },
}

22:03 >

Hope that helps,

[aditya1977]

Thanks so much for your help guys. I mostly get this now!

Just one last question. If I wanted to return the attributes of one of the servers as a hash, how do I get to that data?

So in other words, I want to a create a simple hash %server_properties which name value pairs of one of the servers?

[LanX]

Why don't you try and see? :)

Caution order matters!

PS: and plz have a look at the links provided.

[vinoth.ree]

Hi aditya1977

Lets try this one.

use strict;
use warnings;
use Data::Dumper;

my %nodemetrics;

my @nodelist = qw(server1 server2);

my @system_attributes = qw(memory cpu disk network);

# Initialise the hash with zeros

my ($node);
foreach $node (@nodelist) {

        foreach (@system_attributes){
                $nodemetrics{$node}{$_} = 0;
        }
}

print Dumper(\%nodemetrics);

my $string="1024|2200|30|100";
my @data = split(/\|/,$string);

my @keys = keys %{$nodemetrics{'server1'}};

my $hashref = $nodemetrics{'server1'};

@$hashref{@keys}=@data;
$nodemetrics{'server1'}=$hashref;
print Dumper (\%nodemetrics);

[Monk::Thomas]

my @keys = keys %{$nodemetrics{'server1'}};

in a somewhat recent perl this leads to:

$ perl scratch.pl 
[...]
          'server1' => {
                         'memory' => '1024',
                         'network' => '2200',
                         'cpu' => '30',
                         'disk' => '100'
                       },
[...]

$ perl scratch.pl
[...]
          'server1' => {
                         'disk' => '1024',
                         'memory' => '2200',
                         'cpu' => '30',
                         'network' => '100'
                       }
[...]

OUCH!!

You already have the keys in the correct order available, why not use that?

my @system_attributes = qw(memory cpu disk network);

[...]

my $hashref = $nodemetrics{'server1'};
@$hashref{@system_attributes}=@data;