Having difficulties with "split"

[andybshaker]

Hi everyone, I have an array called @Coordinates where each element looks like 1111111..2222222, 3333333..4444444, 5555555..6666666, etc. They are not all the same number, obviously--that is just an example. The point is that in each element, there are 7 or 8 numbers separated by ".." . What I need to do is make an array with elements 1111111, 2222222, 3333333, 4444444, 5555555, 6666666, etc. I tried using a foreach loop with

foreach my $C (@Coordinates){
push (@NewCoordinates, split("..",$C)};

to no avail. Does anyone have suggestions? Also, I just want to say how helpful this website is. I don't know where I'd be without it.

[LanX]

Split takes a regex (not a string) as first argument and . is a meta character in regexes.

Try escaping with /\.\./

HTH :)

update

  DB<100> split "..", "1..2..3"
 => ("", "", "", 3)

  DB<101> split /\.\./, "1..2..3"
 => (1, 2, 3)

[AnomalousMonk]

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my @coords = qw(1111111..2222222  3333333..4444444  5555555..6666666)
+;
 dd \@coords;
 ;;
 my @new_coords = map { split m{ \.\. }xms } @coords;
 dd \@new_coords;
"
["1111111..2222222", "3333333..4444444", "5555555..6666666"]

[1111111, 2222222, 3333333, 4444444, 5555555, 6666666]

In a regex (which is what split takes as its first argument), the  . (dot) is a metacharacter meaning "match anything except a newline unless the  /s modifier is asserted, then match anything", so  . must be escaped in some way. See perlre, perlretut.

[Laurent_R]

The dot has a special meaning in regexes.

Try this (untested):

foreach my $C (@Coordinates){
    push (@NewCoordinates, split /\.\./, $C);
};

[MidLifeXis]

Instead of escaping the dots explicitly, you could set the RE to escape special characters for you. This is useful when you may need to expand an arbitrary delimiter.

@foo = split("\Q$delim\E", $string);

[Anonymous Monk]

General rule: when you know what you don't want, use split. When you know what you WANT, use regex.

push (@NewCoordinates, $C =~ /\d{7,8}/g);

[Anonymous Monk]

# then again, even the "map" is not needed

@NewCoordinates = "@Coordinates" =~ /\d+/g;

[Anonymous Monk]

# no need for a "for" loop

@NewCoordinates = map /\d+/g, @Coordinates;

[Anonymous Monk]

Oops, I misread as 7 or 8 digit numbers. just use /\d+/g for the regex.