XML::LibXML::Element appendChild/addChild not inheriting namespace?

[szr]

I feel there is something I'm missing in regards to namespace inheritance in XML::LibXML. Please consider the following:

<?xml version="1.0"?>
<root xmlns:foo="http://foo"><parent><foo:child/></parent></root>

Element foo:child is valid without a xmlns:foo="http://foo" attribute since that appears further up the tree, in the root node. What I don't quite understand is the behavior of addChild or appendChild of XML::LibXML::Node which doesn't seem to realize that prefix is associated with a namespace further up the tree (in the root node) and doesn't properly split foo:child.

use strict;
use warnings;

use XML::LibXML;

my $d = XML::LibXML::Document->new;
$d->setDocumentElement(  my $r = $d->createElement( q{root} )  );
$r->setNamespace( q{http://foo}, q{foo}, 0 );
my $p = $r->addChild(  $d->createElement( q{parent} )  );
my $c = $p->addChild(  $d->createElement( q{foo:child} )  );

printf qq{child->prefix=%s, child->localname=%s\n}, $c->prefix, $c->lo
+calname;

Which yields: child->prefix=, child->localname=foo:child
When I would have expected: child->prefix=foo, child->localname=child

I know createElementNS can be used, but that requires one to know what NS to pass rather than being able to rely on inheritance. What is even stranger is inheritance actually appears to work with attributes. If I add the following to the code above:

$c->setAttribute( q{foo:abc}, q{123} );
my $an = $c->getAttributeNode( q{foo:abc} );
printf qq{an->prefix=%s, an->name=%s\n}, $an->prefix, $an->name;

I get this: an->prefix=foo, an->name=abc

Also note the lack of using setAttributeNS method, as this is about inheritance, rather than manually specifying the namespace uri each time an attribute is added.

So why doesn't this seem to work for elements? Maybe I'm really missing something, probably fairly obvious, as it seems this should be trivial.

Thanks.

[choroba]

If you want to add a new child with a namespace, use addNewChild:

my $c = $p->addNewChild('http://foo', 'child');

If you need to use the prefix and inheritance, combine it with lookupNamespaceURI:

my $c = $p->addNewChild($p->lookupNamespaceURI('foo'), 'child');

[szr]

Thank you for the reply. Yes, your method appears to work.

One thing is still bugging me though, in regards to $child->localname yielding foo:child, which doesn't seem to be XML 1.0 compliant, as a colon usually isn't allowed in the localname or prefix parts, as it's reserved as the separator, yet localname contains it in my original test case above.

Would this constitute a bug, or is this desired behavior somehow?

[choroba]

I think the problem is already in createElement which accepts 'foo:child' without checking the prefix. I'm not sure whether it's a problem on the Perl or underlying C side, though.