Problem with nested array/hashes

[Dandello]

@AoH = ({'key1' => 'value1', 'key2' => 'value2', 'key3' => [{'var1 => 
+'val1', 'var2' => 'val2'}, NEED TO ADD ANOTHER HASH HERE],}
);

I can add another 'key'=>'value', to the first hash (the one with key1), that's not a problem, but I'm having trouble figuring out how to add more hashes to the array in key3. (Indicated by 'NEED TO ADD ANOTHER HASH HERE'

I didn't create the original code but I need to add more to it and the new hash is generated from other variables. This is a much simplified example.

[choroba]

You can either push to the inner array, or you can assign to its particular member:

#!/usr/bin/perl
use warnings;
use strict;

use Data::Dumper;

my @AoH = ({key1 => 'value1',
            key2 => 'value2',
            key3 => [ { var1 => 'val1',
                        var2 => 'val2',
                      },
                      #NEED TO ADD ANOTHER HASH HERE
                    ],
           },
          );

push @{ $AoH[0]{key3} }, { key => 'value' };
#    ^       ^   ^
#    |       |   |
#  deref    0th  |
#  as an    hash |
#  array         key in
#                the hash

$AoH[0]{key3}[2]{another} = 'way'; # if you know the index.

print Dumper \@AoH;

[AnomalousMonk]

Please also see Perl Data Structures Cookbook (perldoc perldsc from the command line).

[stevieb]

This is pretty simple, especially if you're just adding them manually. Might help to look at it formatted:

my @AoH = (
    {
        'key1' => 'value1', 
        'key2' => 'value2', 
        'key3' => [ # aref starts here
            {
                'var1' => 'val1', 
                'var2' => 'val2',
            }, 
            {
                new_hash_key1 => 'val1',
                new_hash_key2 => 'val2'
            }, 
        ],
    },
);

[Dandello]

This: $AoH[0]{key3}[2]{another} = 'way'; was the clue I needed, thanks.

Adding them manually wasn't an option as the actual number of added hashes is dependent on a separate list.