Re: Making a variable from a number in front of a string

[choroba]

I used a flag variable to tell me whether I'm inside the correct section. Also, using `(...)` in a regex creates a capture group, you can add 1 to it as to any other variable. Note that you need to backslash the parentheses to give them their literal meaning.

#!/usr/bin/perl
use warnings;
use strict;

my $printing;
my $next_section = q();
while (<DATA>) {
    if (/^\(([0-9]+)\) .*Significant Accounting Policies/) {
        $printing = 1;
        $next_section = 1 + $1;
    } elsif (/^\($next_section\)\s/) {
        undef $printing;
    }
    print if $printing;
}

__DATA__
(1) Preface

What is this all about.

(2) Summary of Significant Accounting Policies

Revenue Recognition

Revenue is recognized at the time goods are sold and shipped.

(3) Long-term Debt

[porsche5k]

Thanks for the response. Here is a complete newbie question but what goes in "(<DATA>)?"

Is that the file location?

[Laurent_R]

The <DATA> file handle makes it possible to read the __DATA__ section at the end of the program, i.e. in this case:

__DATA__
(1) Preface

What is this all about.

(2) Summary of Significant Accounting Policies

Revenue Recognition

Revenue is recognized at the time goods are sold and shipped.

(3) Long-term Debt

It simulates another file and it is a way to quickly test programs without having to create a separate test input file

[Marshall]

The DATA file handle is actually even a bit cooler than that. To set this up, Perl opens the program for read and then seeks to the first byte after the __DATA__ line. Reading from DATA means that you are actually reading the program file.

It is possible for the program to "read itself", i.e.:

#!/usr/bin/perl
use warnings;
use strict;

## DEMO of reading myself

seek (DATA,0,0) or die "unable to seek $!";
print while <DATA>;


__DATA__
some data would go here

To re-read the DATA section, you could use a tell() to figure out where the initial DATA byte is and then later seek back to that initial byte offset.

[Marshall]

Maybe we didn't give you a crystal clear reply. First, the program should run using the data segment. Then take the data after __DATA__ and put that into "somefile". In the program, you need to add at the beginning,

open FILE, '<', "somefile" or die "unable to open file $!";

Now put FILE everywhere that DATA appears in the program. You will now be reading "somefile" on the disk instead of the __DATA__ section.