Regex problem

[dazz]

Hello
I download a web page that includes data used and remaining data for a mobile connection.
I want to find the two values and convert them from strings to values.

A snippet of the html page is:

<span class="remaining-data">54MB used</span>
<span class="expires-data-right-align">1.44GB remaining</span>

I use the regex to get a matching substring with the 1st value within

  (my $DataUsed) = $stgUsed =~ /"remaining-data">([+-]?(\d*\.)?\d+)(MB
+|GB) used/;  # trying to get just the digits.
  (my $unit) = $stgUsed =~ /(MB|GB)/;  # match either MB or GB
  if ( $unit eq "GB"){  $DataUsed *= 1000; }

The output in $stgUsed is what I expect:

  DB<5> x $stgUsed
0  'class="remaining-data">315MB'

In want to capture just the number (315) and the units (MB) but $DataUsed in undef.
I have tried using $1,$2 ... but they are undef as well.

How to I get the digits substring and the MB/GB substring????

Dazz

[haukex]

You will be doing yourself a huge favor if you use a module to parse HTML instead of regexes. I discussed some of the options for parsing HTML and gave some example code here: "Two classic modules are HTML::Parser and HTML::TreeBuilder, but there are several others, such as Mojo::DOM. If the input is always XHTML, there's XML::Twig and many more XML-based modules."

use warnings;
use strict;
use Data::Dump;
use Mojo::DOM;

my $html = <<'END_HTML';
<span class="remaining-data">54MB used</span>
<span class="expires-data-right-align">1.44GB remaining</span>
END_HTML

my $dom = Mojo::DOM->new($html);
for my $e ($dom->find('span[class="remaining-data"]')->each) {
    dd $e->text;
    my ($val,$unit) = $e->text =~ /([+-]?(?:\d*\.)?\d+)(MB|GB) used/
        or die "Couldn't parse '".$e->text."'";
    dd $val, $unit;
}

__END__

"54MB used"
(54, "MB")

[Corion]

I would restructure the code to be less clever but easier to debug:

if( $html !~ m!<span class="remaining-data">\s*(.*?)used\s*</span>! ) 
+{
    die "Couldn't find 'remaining-data' span in html!";
};
my $remaining = $1;
if( $remaining !~ m!^(\d+(?:\.\d+))(MB|GB)$! ) {
    die "Weirdo string instead of remaining data: [$remaining]";
};
my ($DataUsed, $unit) = ($1,$2);