array push fails

[rsFalse]

Hello,

I've tried to use push() on array, but program tells me an error.

#!/usr/bin/perl

use warnings;
use strict;

my @numbers = 6 .. 9;
my @odd = ( 1, 5, 3 );
my @even = ( 4, 10 );

$\ = $/; $, = ' ';

map { print( ( $_ % 2 ? @odd : @even ), "+$_" ) } @numbers;
map { push( ( $_ % 2 ? @odd : @even ), "+$_" ) } @numbers;

OUTPUT:

4 10 +6
1 5 3 +7
4 10 +8
1 5 3 +9
Not an ARRAY reference at ./push_fail.pl line 13.

How can I correctly push using "?:" operator?

[NetWallah]

map { push( @{$_ % 2 ? \@odd : \@even }, "+$_" ) } @numbers;

On my (perl 5.24) system, your original code says:

Experimental push on scalar is now forbidden at pf.pl line 13, near ""
++$_" ) "

Update: BTW - "map" is not the best choice for this code, because you are throwing away the result of the map.

Preferred, and more concise:

 push( @{$_ % 2 ? \@odd : \@even }, "+$_" ) for @numbers;

Then there is room for optimization:

my @evenodd = (\@even, \@odd);
push( @{$evenodd[$_ % 2]}, "+$_" ) for @numbers;

[Cristoforo]

You can push to the odd/even array by looking at this example from perlfaq4.

https://metacpan.org/pod/distribution/perlfaq/lib/perlfaq4.pod#How-do-I-compute-the-difference-of-two-arrays?-How-do-I-compute-the-intersection-of-two-arrays?

[rsFalse]

Thank you guys for answers and links! ;)

[Mr. Muskrat]

NetWallah++ for beating me to the answer. :)

This has been asked before... See also: Using ternary operator as lvalue in push.