clipboard and unicode text

[Animor]

Hi, I'm using Active Perl 5.24 on Windows 10. I'm trying to set Unicode text to clipboard, using Win32::Clipboard, however when I paste the clipboard I get "Gibberish" for the Unicode characters. Is there a simple way of doing it? I saw in an old thread that using Win32::API with SetClipboardData and CF_UNICODETEXT should work, but I'm not sure how to use it. Looks like SetClipboardData is expecting to get some kind of a handle. Any help is appreciated.

[vr]

Win32::Clipboard won't place Unicode text on Clipboard by design:

CF_TEXT ... is the only format you can use to set clipboard data

This is what works for me (written based on that):

use strict;
use warnings;

use Win32::API 'WriteMemory';
use Encode     'encode';

Win32::API-> Import( 'kernel32', 'HGLOBAL  GlobalAlloc( UINT uFlags, S
+IZE_T dwBytes )' )    or die;
Win32::API-> Import( 'kernel32', 'UINT_PTR GlobalLock( HGLOBAL hMem )'
+ )                    or die;
Win32::API-> Import( 'kernel32', 'BOOL     GlobalUnlock( HGLOBAL hMem 
+)' )                  or die;
Win32::API-> Import( 'kernel32', 'HGLOBAL  GlobalFree( HGLOBAL hMem )'
+ )                    or die;

Win32::API-> Import( 'user32',   'BOOL     OpenClipboard( HWND hWndNew
+Owner )' )            or die;
Win32::API-> Import( 'user32',   'HANDLE   SetClipboardData( UINT uFor
+mat, HANDLE hMem )' ) or die;
Win32::API-> Import( 'user32',   'BOOL     CloseClipboard( )' )       
+                      or die;

my $str = "\x{05d0}\x{05d1}\x{05d2}";               # Alef Bet Gimel
my $buf = encode( 'UTF16LE', $str ) . "\0\0";
my $h   = GlobalAlloc( 2, length $buf ) or die;     # GMEM_MOVEABLE
my $p   = GlobalLock( $h )              or die;

WriteMemory( $p, $buf, length $buf );
GlobalUnlock( $h );

OpenClipboard( 0 )         or die;
SetClipboardData( 13, $h ) or die;                  # CF_UNICODETEXT
CloseClipboard()           or die;

GlobalFree( $h );

P.S. If your ANSI CP is 1255 (mine isn't, so I tested with another esoteric CP), and you don't mind appended newline, you could simply do this:

use Encode 'encode';

my $str = encode 'CP1255', "\x{05d0}\x{05d1}\x{05d2}";
system "echo $str| clip";

P.P.S. BTW, can anyone enlighten me, how Perl encodes argument to system, on Windows? Can this encoding be changed?

use strict;
use warnings;
use Encode 'encode';

my $str = encode 'CP1255', "\x{05d0}\x{05d1}\x{05d2}";
system "echo $str";

Output from Perl script still corresponds to my original CP1251.

C:\>mode con cp select=1255

Status for device CON:
----------------------
    Lines:          9000
    Columns:        80
    Keyboard rate:  31
    Keyboard delay: 1
    Code page:      1255


C:\>echo אבג
אבג

C:\>perl 171116.pl
абв

[Animor]

Thank you very much! The first method seems to work fine.

[Anonymous Monk]

Hi,

Do you have sample code?

[Animor]

Yes, this is an example of what I'm trying to do:

use Win32::Clipboard;
use utf8;

tie my $clipboard, 'Win32::Clipboard';
my $text = "אושרי"; # please note that I
+ wrote here a unicode string (Hebrew chars), but this forum changed i
+t automatically to these numbers (ASCII I guess)
$clipboard = $text;

Then, outside of the program, I try to paste (using ctrl-v) the unicode string. I get "Gibberish". I also tried the following, which didn't work:

utf8::decode($text);
utf8::encode($text);

[Anonymous Monk]

Where are you pasting?