Mixing OR with conditional operator

[jockel]

Hi

Can someone please explain this behavior. I was surprised with result of the following code. (And please help me come up with a better Title for this question)

I think the variable $test should be set to $val1 (1) but instead it gets set to $val2 (undef)

#/usr/bin/perl
use strict;
my $test;
$test = 1 || (undef && undef != 0) ? undef : 0; 

print "test = $test\n";

OUTPUT:
test =

[choroba]

It's a precedence problem.

B::Deparse with the -p option can show you how Perl understands expressions. Unfortunately, the expression contains only constants, so it's evaluated at compile time, so the result isn't helpful:

$ perl -MO=Deparse,-p 1.pl
use strict;
my($test);
($test = (undef));
print("test = $test\n");
1.pl syntax OK

You need to introduce variables to postpone the evaluation to runtime to get a more enlightening answer:

#! /usr/bin/perl
use warnings;
use strict;

my $test;
my $undef;
my $true = 1;
my $zero = 0;

$test = $true || ($undef && $undef != $zero) ? $undef : $zero;

print "test = $test\n";

And, voilą:

use strict;
my($test);
my($undef);
(my $true = 1);
(my $zero = 0);
($test = (($true || ($undef && ($undef != $zero))) ? $undef : $zero));
print("test = $test\n");
1.pl syntax OK

Nicely indented:

$test = (
    (
        $true || (
            $undef && (
                $undef != $zero
            )
        )
    ) ? $undef : $zero
)

$true || ... returns 1, so the "then" part of the ternary is returned, i.e. $undef.

Maybe you wanted

$test = $true || ($undef && $undef != $zero ? $undef : $zero);

[jockel]

Choroba,

I have variables in my real code, I just thought I would simplify it as much as possible.

Actually I first wrote an example just like your last example. But I didn't think my 'simplification' would actually change the whole behavior!

OT: The current "Voting Booth"-question "In order to be able to say "I know Perl", you must have:", with the leading answer "One can never truly know perl", are totally correct ;-)

Edit: And yes, your last one liner code-example, fixes the issue and I will adopt that syntax!

Thank you!

[LanX]

> One can never truly know perl

This problem is not Perl specific, you need to respect precedence in all languages.*

Just try to do the same expression in JS or C ...

update

*) correction, most not all. You might enjoy Lisp or Assembler.

[BrowserUk]

Try adding 'use warnings'. ( Use of uninitialized value in numeric ne (!=) )

[jockel]

Hmm.

I get no warning for row 5, only for row 7.

Use of uninitialized value $test in concatenation (.) or string at /tmp/test2.pl line 7.

Still, shouldn't the '1' before the OR evaluate first, and just skip everything after the OR?

[Anonymous Monk]

Speaking generally, there are always three issues:
1. Operator precedence: In algebra, 1 + 2 * 3 is always 7, not 6.
2. Bitwise operators: Does, say, "&&" mean "logical and" or "bitwise and?" Is 7 && 16 ... true, or integer 0?
3. Short-circuiting: The computer stops evaluating a logical expression that is joined by "and" and "or" operators as soon as possible. If you are counting on "side effects" from the entire expression, some of them might not happen.

[Anonymous Monk]

In algebra, 1 + 2 * 3 is always 7, not 6.

in what world would it ever be 6?

[soonix]

in a world where you stand on your head   ,-)
(and have different precedences, of course)

[Anonymous Monk]

I'm sure that was supposed to be "9" but the point is made. Anyhow, "parentheses are your bestest friend," and so is splitting a complicated expression into several smaller ones using temporary local variables. Write the source-code so that people can understand it at a glance. Compilers and interpreters can take care of themselves. Troubles begin when people mis-read what is put in front of them.