Re: Re: Re: Re: Tribute to TMTOWTDI

[chipmunk]

Regardless of any contortions Benchmark goes through to execute code in the calling package, lexical variables are not in any package. It is impossible for code to access lexical variables that are not in scope.

This can be seen with a very simple Benchmark:

#!perl

use Benchmark;

$main::variable = 'global';
my $variable = 'lexical';

timethese(1,
          {
           anon   => sub { print "$variable\n"; },
           string => 'print "$variable\n";',
          }
         );
__END__
Benchmark: timing 1 iterations of anon, string...
lexical
      anon:  0 wallclock secs ( 0.00 usr +  0.00 sys =  0.00 CPU)
            (warning: too few iterations for a reliable count)
global
    string:  0 wallclock secs ( 0.00 usr +  0.00 sys =  0.00 CPU)
            (warning: too few iterations for a reliable count)

The anonymous sub snippet accesses the lexical $variable, because the snippet is compiled in the same scope as the lexical variable. The string snippet accesses the global $variable, because the snippet is compiled in a completely separate scope, when the eval is executed.

[demerphq]

Regardless of any contortions Benchmark goes through to execute code in the calling package, lexical variables are not in any package. It is impossible for code to access lexical variables that are not in scope.

No arguments here. My only problem with your post was the line I quoted. I've just reread your original post and you have to admit its a little ambiguous. Yes the code is executed inside of the _file_ Benchmark, but not in the package Benchmark. And this leads to an interesting point (about which Ill have to trawl the docs for at a later time) the two are different. Consider the below code

#Put in file TestA.pm in a root lib directory
package TestA;
my $var="TestA";
1;

#Put in file TestB.pm in a root lib directory
package TestB;
use TestA;
my $var2="TestB";

package TestA;
print "'$var','$var2'";
1;

Now if you do perl TestB.pm you will see

'','TestB'

But if you stick the entire code snippet into TestB.pm then you will see

'TestA','TestB'

Even though you might expect that the lexical variable $var would be out of scope.

_{(Incidentally I have a development Lib directory that I use for this type of stuff and have my enviornment configured to always include it.)}
Update
It seems to me the moral of this is that when you put many packages in a single file everything following the package declaration should be placed into an anoymous block. Ie:

package TestA;
{
  my $var="TestA";
  1;
}

package TestB;
{
  use TestA;
  my $var2="TestB";
}
package TestA;
{
  print "'$var','$var2'";
  1;
}


Yves / DeMerphq
--
Have you registered your Name Space?