Re: LWP::UserAgent and Cookies

[athomason]

Sure, just set up a cookie jar using HTTP::Cookies:

use strict;
use LWP::UserAgent;
use HTTP::Cookies;
use HTTP::Request::Common;

my $cookie_jar = HTTP::Cookies->new( );
my $ua = LWP::UserAgent->new;

$ua->cookie_jar( $cookie_jar );

my $request = GET "http://www.doubleclick.net"; # don't worry, it does
+n't get saved :-)

my $response = $ua->request( $request );

$cookie_jar->extract_cookies( $response );

print $cookie_jar->as_string;

Subsequent requests using the same user agent will send those cookies to the server. If you don't want them to be sent, use a new agent or clear the jar with $cookie_jar->clear.

When you say the server requires that the client accept a cookie, presumably you mean that the cookie must be kept around in order to retrieve another page correctly. Because when serving the first page, the server has no idea whether the user will keep the cookie (i.e. send it back later). If you mean it must remember it and send it back, you'll want to reuse the user agent (and cookie jar) as mentioned above. If you want to preserve the cookie jar for later use outside your script, take a look at the save and load methods in HTTP::Cookies. For a longer discussion of this subject, check out perldoc lwpcook and poke through the Q&A section under the HTTP and FTP clients topic.

[IlyaM]

Just a note:

You don't need

$cookie_jar->extract_cookies( $response );

If cookie jar object is set for user agent object than user agent does this itself.

--
Ilya Martynov (http://martynov.org/)

[jczeus]

This is a very old thread, but having just tried myself I noticed that the cookie is not set if I don't make that method call.

Although not needed in my example, I used a file for saving the cookie just to check the session-ID, and the file stayed empty without that call. Any thoughts?

[hippo]

This works fine for me:

#!/usr/bin/env perl
use strict;
use warnings;
use LWP::UserAgent;
use HTTP::Cookies;
use Test::More tests => 1;

my $cookie_jar = HTTP::Cookies->new;
my $ua         = LWP::UserAgent->new;

$ua->cookie_jar ($cookie_jar);

my $response = $ua->get ('https://twitter.com/');

like $cookie_jar->as_string, qr/guest_id=/, 'Cookie retrieved';

HTTP::Cookies 6.01, LWP::UserAgent 6.15.