One approach is to use a parser like Parse::RecDescent. A real parser (as opposed to parsing a string with a regular expression alone) is much more powerful and can be more apropriate for parsing highly structured/nested data like your example.

use Parse::RecDescent;
my $teststr="a,b,op2(c,d),op3(e,op4(f,g))";
my $grammar = q {
        content:        /[^\)\(\,]+/
        function:       content '(' list ')'
        value:          content
        item:           function | value
        list:           item ',' list | item
        startrule:      list
};
my $parser = new Parse::RecDescent ($grammar) or die "Bad grammar!\n";
defined $parser->startrule($teststr) or print "Bad text!\n";
[download]

This should work more reliably in case there are repeated strings:

$_ = "a,b,op2(c,d),(e),(f),(f,g),op3(e,op4(f,g))\n";
print;
($re=$_)=~s/((\()|(\))|.)/$2\Q$1\E$3/gs;
@$ = (eval{/$re/});
die $@ if $@=~/unmatched/;
$re = join'|',map{quotemeta}@$;
print join"\n",/((?:$re|[^,])+)/g;
[download]

lhoward's grammar seems unnecessarily complicated. Let's simplify it a bit, as well as grabbing what is needed for the answer (the split items):

use Parse::RecDescent; 
my $teststr="a,b,op2(c,d),op3(e,op4(f,g))"; 
my $grammar = q {
startrule: list
list: <leftop: item ',' item>
item: word '(' list ')' <commit> { "$item[1](".join(",",@{$item[3]})."
+)" }
    | word
word: /\w+/ 
}; 
my $parser = new Parse::RecDescent ($grammar) or die "Bad grammar!\n";
+ 
defined (my $result = $parser->startrule($teststr)) or print "Bad text
+!\n";
print map "<<< $_ >>>\n", @$result;
[download]