How do I print/round a number to a given number of decimal places?

[vroom]

How do I print/round a number to a given number of decimal places?

Originally posted as a Categorized Question.

[vroom]

Probably the easiest way is to use printf/sprintf:

$unrounded = 0.66666;

printf "$unrounded rounded to 3 decimal places is %.3f\n", $unrounded;

$rounded = sprintf "%.2f", $a;  # rounded to 2 decimal places (0.67)

[hossman]

As in How do I round a number? — Math::Round has a great method for this:

use Math::Round;

print nearest(.01, 1.555);

[Roy Johnson]

This other answer, by wrvhage, has the great property of working correctly for values like 3.005 rounded to two places (where sprintf is not). However, it needs a couple of tweaks to work for negative numbers.

sub stround
{
    my( $n, $places ) = @_;
    my $sign = ($n < 0) ? '-' : '';
    my $abs = abs $n;
    $sign . substr( $abs + ( '0.' . '0' x $places . '5' ), 0, $places 
++ length(int($abs)) + 1 );
}

[wrvhage]

sub stround
{
    my( $number, $decimals ) = @_;
    substr( $number + ( '0.' . '0' x $decimals . '5' ), 0, $decimals +
+ length(int($number)) + 1 );
}

TIMTOWTDI!

[littleskittles]

This answer by Roy Johnson improved this answer by wrvhage by dealing with negative numbers. This answer adds an improvement to handle the case where decimal places is zero, i.e. by not including the hanging decimal point, e.g. "10.1" rounded to zero places would become "10." instead of "10". Any other changes are just rearrangement of the code.

sub stround
{
  my ($n, $places) = @_;
  my $abs = abs $n;
  my $val = substr($abs + ('0.' . '0' x $places . '5'),
                   0,
                   length(int($abs)) +
                     (($places > 0) ? $places + 1 : 0)
                  );
  ($n < 0) ? "-" . $val : $val;
}

[Munkey]

Perhaps not as fast as printf, but pretty fast, and not using anything special:

sub round {

    my ($nr,$decimals) = @_;
    return (-1)*(int(abs($nr)*(10**$decimals) +.5 ) / (10**$decimals))
+ if $nr<0;
    return int( $nr*(10**$decimals) +.5 ) / (10**$decimals);

}

strange that no-one has posted this, seems like the most straightforward idea to me...

[Anonymous Monk]

444.7767655

Originally posted as a Categorized Answer.