Re: Re: Scoping issues with code evaluation asserstions?

[Cirollo]

in reply to Re: Scoping issues with code evaluation asserstions?
in thread Scoping issues with code evaluation asserstions?

That was my first thought, but it didn't make much sense to me. Maybe my understanding of scoping isn't quite as good as I thought, but I thought that you had to declare a variable outside of the scope of the sub in order to create a closure.

Could it be that the one-time compilation of the regex somehow causes the closure?

Also, saying local $ret = ''; breaks under strict:

Variable "$ret" is not imported at /home/apirkle/bin/retest.pl line 8.
Global symbol "$ret" requires explicit package name at /home/apirkle/b
+in/retest.pl line 6.
Global symbol "$ret" requires explicit package name at /home/apirkle/b
+in/retest.pl line 8.

[diotalevi]

You'd need to have declared $ret as a global somewhere for local to localize it. Remember that local() declares nothing.

use vars '$ret';
sub regex {
    local $ret = '';

What you didn't realize was that the (?{ ... }) is a closure so when it first ran it captured the original $ret and continued to write to that same instance which wasn't the same one being returned in later iterations.

[sauoq]

Could it be that the one-time compilation of the regex somehow causes the closure?

That's exactly what it is. Your regex() sub isn't the closure, the code in the regular expression code assertion is.

Also, saying local $ret = ''; breaks under strict:

Well of course it does. :-) (I should have mentioned that though.) Use our $ret = ''; or declare $ret with use vars qw( $ret ); instead. And keep in mind that whichever way you choose to declare it, it's still a global variable.

-sauoq
"My two cents aren't worth a dime.";

[diotalevi]

I have this clever idea to have the function use its own name as the slot for the return value.

sub regex {
    my $in = shift;

    # Assign something to $ret in a code assertion
    my $function = (caller 0)[3];
    no strict 'refs';
    $$function = '';
    $in =~ m/^(a)(?{ $$function = 1})/;

    return $$function;
}

while(<DATA>) {
    print regex($_) . ".";
}

__DATA__
a
b
a
abcd
bcda

[sauoq]

I think that's a bit too clever. What if there is a global variable named $regex? You've just clobbered it. I think creating a local alias is probably better.

use strict;
use warnings;
sub regex {
    my $in = shift;
    my $ret = '';

    # Assign something to $ret in a code assertion
    local *alias = \$ret; 
    $in =~ m/^(a)(?{ $alias = 1})/;

    return $ret;
}

while(<DATA>) {
    print regex($_) . ".";
}
print "\n";

__DATA__
a
b
a
abcd
bcda

-sauoq
"My two cents aren't worth a dime.";