dynamic symbol Exporter

[bsdz]

Is it possible to export symbols dynamically in a module? For example: -

package A;

use strict;

require Exporter;
our @ISA    = qw(Exporter);
our @EXPORT = qw( build_funcs );

sub build_funcs {

    foreach ('A', 'B', 'C') {
        eval  "
        print \"building $_ func\\n\";
        sub ${_}_func {
            print \"$_ func called\\n\";
        }
        ";
        push @EXPORT, "${_}func";
    }
}
1;

Using a test function like: -

use strict;
use lib '.';
use A;

&build_funcs;

&A_func;

Any experience with this one?

[broquaint]

It is indeed possible. Perhaps you want something like this

sub build_functions {
  my(@funcs, $pkg) = (@_, scalar caller);

  for my $f (@funcs) {
    *{"$pkg\::$f"} = sub { print "I am &$f\n" };
  }
}

build_functions qw/ foo bar baz /;

foo(), bar(), baz();

__output__

I am &foo
I am &bar
I am &baz

So that just creates the given arguments as dummy functions in the caller's symbol table. See. caller and Of Symbol Tables and Globs for more info.

[simonm]

Building subs and pushing them onto @EXPORT or @EXPORT_OK isn't uncommon; I use this same technique in Text::MicroMason.

However, looking at your code, I think you'll need to move the &build_funcs; call to the end of package A, so that it's executed before the use A completes.

[!1]

Your code is just defining the subroutines within the A namespace. You could use caller to return the namespace in which you want the subroutine exported.

sub build_funcs {
    my $package = caller;
    foreach ('A', 'B', 'C') {
        eval  "
        print \"building $_ func\\n\";
        sub $package\::${_}_func {
            print \"$_ func called\\n\";
        }
        ";
        push @EXPORT, "${_}func";
    }
}

Of course, you could also use AutoLoader in combination with @ISA in your test script to have an AUTOLOAD that creates the subroutine for you. Also, on a side note, don't get in the habit of calling subroutines as &sub unless you know why you're doing it. Instead use sub(). Read perldoc perlsub for more information about it. I hope this helps you with your problem.

[bsb]

Depending on the real context, you man also want to write you own import routine. perlmod for details.