Ever since I've read about them, I've been fascinated by spigot algorithms for producing digits of pi.
The basic idea for those algorithms is that most "interesting" transcendental numbers (like pi, e, ln(2)) have a pretty simple representation if the base is allowed (in a regular pattern) for each digit. Then the task of computing the first $N first digits is just that of a base conversion. And the fascinating part is that you can work with integers only-
To stay a bit on topic, I've ported this C implementation of a spigot algorithm for pi to Perl 6:
sub pi-spigot(Int $digits) {
my $len = 1 + floor 10 * $digits / 3;
my @a = 2 xx $len;
my Int $nines = 0;
my Int $predigit = 0;
join '', gather for 1 .. ($digits + 1) -> $j {
my Int $q = 0;
loop (my int $i = $len; $i > 0; $i = $i - 1) {
my int $x = 10 * @a[$i - 1] + $q * $i;
@a[$i - 1] = $x % ( 2 * $i - 1);
$q = $x div (2 * $i - 1);
}
@a[0] = $q % 10;
$q div= 10;
if $q == 9 {
++$nines;
}
elsif $q == 10 {
take $predigit + 1, 0 xx $nines;
$nines = 0;
$predigit = 0;
}
else {
take $predigit;
$predigit = $q;
take 9 xx $nines;
$nines = 0;
}
}
}
multi MAIN($n = 100) {
say pi-spigot($n.Int);
}
multi MAIN('test') {
use Test;
plan 1;
is pi-spigot(100),
'03141592653589793238462643383279502884197169399375105820974944
+59230781640628620899862803482534211706',
'it works';
}
Since Rakudo is still pretty slow for this kind of stuff, I've traded a bit of readabilty for speed by using a native int in the inner loop, which means that Rakudo can inline most operators, but means I have to write $i = $i - 1 instead of $i-- (because native ints are value types, and you cannot (yet?) pass them as writable values to routines, so the -- operator cannot work on them).
-
Are you posting in the right place? Check out Where do I post X? to know for sure.
-
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big>
<blockquote> <br /> <dd>
<dl> <dt> <em> <font>
<h1> <h2> <h3> <h4>
<h5> <h6> <hr /> <i>
<li> <nbsp> <ol> <p>
<small> <strike> <strong>
<sub> <sup> <table>
<td> <th> <tr> <tt>
<u> <ul>
-
Snippets of code should be wrapped in
<code> tags not
<pre> tags. In fact, <pre>
tags should generally be avoided. If they must
be used, extreme care should be
taken to ensure that their contents do not
have long lines (<70 chars), in order to prevent
horizontal scrolling (and possible janitor
intervention).
-
Want more info? How to link
or How to display code and escape characters
are good places to start.