my @files = <DATA>;
chomp @files;
my @sorted = map  {   $_->[0] } 
             sort {   $a->[1] cmp $b->[1] }
             map  { [ $_ , ( split /\s+/, $_ )[-1] ] }
             @files;

print "$_\n" for @sorted;

__DATA__
1999-12-07 12:00p 3,856 abc.dll
2002-02-24 09:30p 260,096 xyz.dll
2004-03-19 01:29p 992,907 lmo.dll
2004-04-08 03:23p 24,576 efg.dll
2004-03-11 0804a 1,036,288 stu.dll
[download]

For an explanation, look up Schwartzian Transform.

This is, of course, just One Way To Do It. Here come the rest..........

@arr=sort {split(/\s+/,$a)[-1] cmp split(/\s+/,$b)} @arr;
[download]

For a more serious routine, you could pick the line apart with a regular expression, change the array into a list of lists that contains the filename as one element and the original line as the other, sort based on the filename element, and in the final step throw the filename away, leaving the sorted list of lines. This is known as Schwartzian transform.

#!/usr/bin/perl
use strict;
use warnings;

my %file;
while ( <DATA> ) {
    chomp;
    my @info = split " ";
    $file{ $info[3] } = $_;
}
print "$file{$_}\n" for sort keys %file;
__DATA__
1999-12-07 12:00p 3,856 abc.dll
2002-02-24 09:30p 260,096 xyz.dll
2004-03-19 01:29p 992,907 lmo.dll
2004-04-08 03:23p 24,576 efg.dll
2004-03-11 08:04a 1,036,288 stu.dll
[download]

#!/usr/bin/perl
use strict;
use warnings;

for ( sort glob "*.dll" ) {
    print "$_ : ", -s, "\n";
}
[download]

Cheers - L~R

Do not forget that you can use the glob function to get all the file names that end in .dll then use the file test operators to get that information then do the alpha sort.