Beefy Boxes and Bandwidth Generously Provided by pair Networks
Do you know where your variables are?
 
PerlMonks  

Re: How to sort an array

by jarich (Curate)
on Jul 07, 2004 at 13:23 UTC ( #372377=note: print w/ replies, xml ) Need Help??


in reply to How to sort an array

Just to be clear, you have an array consisting of lines like the one you describe above? So your data could be constructed with something like the following?

my @Data = ( "1|someproject|active...", "2|somethingelse|finished..." );
If that is correct, then you can use something like the following to achieve your aim:
#!/usr/bin/perl -wT use strict; # position to sort by my $sortbyfield = 3; my @input = ( '1|2|1|4|5|6|7|8|9', '1|2|2|5|5|6|7|8|9', '1|2|0|1|5|6|7|8|9', '1|2|9|2|5|6|7|8|9', '1|2|8|3|5|6|7|8|9', '1|2|7|4|5|6|7|8|9', '1|2|6|7|5|6|7|8|9', ); # Schwartzian Transform my @output = map { $_->[0] } sort { $a->[1] <=> $b->[1] } map { [$_, getfieldvalue($_, $sortbyfield)] } @input; print join( "\n", @output), "\n"; sub getfieldvalue { my ($line, $fieldno) = @_; my @items = split /\|/, $line; return $items[$fieldno]; } __END__ returns (sorted by 3rd _position, arrays start at 0) 1|2|0|1|5|6|7|8|9 1|2|9|2|5|6|7|8|9 1|2|8|3|5|6|7|8|9 1|2|1|4|5|6|7|8|9 1|2|7|4|5|6|7|8|9 1|2|2|5|5|6|7|8|9 1|2|6|7|5|6|7|8|9
Please note that the above will only work for numeric input. You can change it to use string compare by replacing the <=> with cmp.

I would suggest thinking about what you're doing with this data, however. If you're going to be accessing bits of it more than just this time, then perhaps you should be using an array of hashes or at least and array of arrays? See perlreftut.

If you break this into an array of hashes:

my @fields = qw/id projname status submitdt assign_dt total complete_dt person dept closed_dt/; # Create my array of hashes. foreach (@Data) { my %hash; @hash{@fields} = split /\|/, $_; $_ = \%hash; }
You can access individual items as follows:
print "The id of the project in Data[0] is $Data[0]{id}\n";
This might make it easier to sort, too.
my @sorted = sort {$a->{projname} cmp $b->{projname}} @Data; # To get the same kind of format as before ... foreach (@sorted) { my %temp = %$_; print "@temp{@fields}\n"; }
As I said, it depends on how much manipulation is required on the input.

I hope this helps

jarich


Comment on Re: How to sort an array
Select or Download Code

Log In?
Username:
Password:

What's my password?
Create A New User
Node Status?
node history
Node Type: note [id://372377]
help
Chatterbox?
and the web crawler heard nothing...

How do I use this? | Other CB clients
Other Users?
Others studying the Monastery: (8)
As of 2014-11-23 20:17 GMT
Sections?
Information?
Find Nodes?
Leftovers?
    Voting Booth?

    My preferred Perl binaries come from:














    Results (134 votes), past polls