Re: Keeping the user informed: A Tk/Threads question

[BrowserUk]

Here ya go. Put the long running code into the work() sub and periodically update $progress (as shown) with a value between 0-100.

#!perl -slw
use strict;
use threads qw[ async ];
use threads::shared;

our $WORKMAX ||= 1_000;

## A shared var to communicate progess between work thread and TK
my $progress : shared = 0; 

sub work{
    for my $item ( 0 .. $WORKMAX ) {
        { lock $progress; $progress = ( $item / $WORKMAX ) * 100; }
        select undef, undef, undef, 0.001; ## do stuff that takes time
    }
}

threads->new( \&work )->detach;

## For lowest memory consumption require (not use)
## Tk::* after you've started the work thread.
require Tk::ProgressBar;

my $mw = MainWindow->new;
my $pb = $mw->ProgressBar()->pack();

my $repeat;
$repeat = $mw->repeat( 100 => sub { 
    print $progress;
    $repeat->cancel if $progress == 100;
    $pb->value( $progress ) } 
);


$mw->MainLoop;

[Grygonos]

You must be really bored today :) Thanks for the sample code. I haven't done perl threads before, although I'm pretty experienced with Java's threads, and have done threads in C before. I'm gonna read up on it a bit and see what comes of it. Thanks again :)

---

Grygonos