Re: Why is a hash the default "object" in oo perl?

[tinita]

hmm, i thought about that and made up some code, just for fun.
i don't know if it's really useful and correct, but it was interesting to think about, so i'm just posting this here.
we're talking just about the object-attributes and the get/set methods, i assume.
so, when i create a class i usually find myself defining an attribute method like:

sub _attr {
  my $self = shift;
  my $name = shift;
  return $self->{"_$name"} unless @_;
  $self->{"_$name"} = shift;
}
sub name { shift->_attr(name => @_); }

so that you can call $obj->name("new name");
(I know i could actually use Class::MethodMaker or something similar...)

now how could we make that more generic?
i thought about defining a pragma 'attribute' that you can use like that:

package Parent;
use attribute sub {
  my $self = shift;
  my $name = shift;
  # we have an ordinary hashref for the object
  return \$self->{"_$name"};
}, [qw(city name)];

package Child;
use base 'Parent';
use attribute sub {
  my $self = shift;
  my $name = shift;
  # object is arrayref, and the attributes are stored in element 0
  return \$self->[0]->{"_$name"};
};

so with that, and the assumption that the module you inherit always uses methods to get/set attributes, you are independent from the implementation, right? here's attribute.pm:

package attribute;
use strict;
use warnings;
sub import {
  my ($self, $sub, $names) = @_;
  my $class = caller();
  no strict 'refs';
  # set the general method
  *{$class . '::_attribute_ref' } = $sub;
  for my $name (@$names) {
    my $string = $class . '::' . $name;
    *{$string} = sub {
      my $self = shift;
      # set method for each attribute
      return ${ $self->_attribute_ref($name) } unless @_;
      ${ $self->_attribute_ref($name) } = shift;
    };
  }
}
1;

update: changed subname '_attribute_set' to '_attribute_ref'
moved readmore tag a little