Check the FAQs for "list" - "perldoc -q list" can help.

my @l1 = qw(education production results);
my @l2 = qw(education joe bob carl production steve results tests);
my %h1; undef @h1{@l1};
my @o2 = grep { not exists $h1{$_} } @l2;
[download]

Bad (undocumented behavior):

undef @h1{@l1}
[download]

Better:

@h1{@l1} = ();
[download]

---

Caution: Contents may have been coded under pressure.

use strict;
use warnings;

my @list1 = qw/education production results/;
my @list2 = qw/education joe bob carl production steve results test/;

print join "\n", notIn(\@list2, \@list1);

sub notIn {
    my (@arr, %hash);
    @hash{@{$_[1]}} = ();
    for (@{$_[0]}) { push @arr, $_ if !exists $hash{$_}; }
    return @arr;
}
[download]

#!/usr/bin/perl -w
use strict;

my %set;
my @list1 = qw(education production results);
my @list2 = qw(education joe bob carl production steve results tests);
@set{@list2} = @list2;
delete @set{@list1};
print map {"$_\n"} keys %set;

I would, very simply, map List2 into a hash and compare that hash to List1, storing the results. As your problem is specified, there is no need to modify list 1.

use strict; 

my @list1 = qw(education production results);
my @list2 = qw(education joe bob carl production steve results test);

my %mapping = map { $_ => undef } @list1;

my (@l2_only); undef @l2_only;
foreach (@list2) {
   push(@l2_only, $_) unless exists $mapping{$_};
}

print 'List 1: ', join(', ', @list1),"\n";
print 'List 2: ', join(', ', @l2_only), "\n";

__END__
The script above prints:
List 1: education, production, results
List 2: joe, bob, carl, steve, test
[download]

#!/usr/bin/perl

use strict;
use warnings;
use diagnostics;

use List::Compare;

my @List1 = qw(education production results);
my @List2 = qw(education joe bob carl production steve results test);

my @OutList1 = @List1;  #Part I is done...

my $lc = List::Compare->new(\@List1, \@List2);


# Get those items which appear (at least once) only in the second list
+.
my @OutList2 = $lc->get_complement;

my $n;
foreach (@OutList2) {print $n++.": $_\n"};
[download]

0: bob
1: carl
2: joe
3: steve
4: test
[download]

Cheers,

Brent

Against my doctors orders, I continue to use:

my @no_dups = do { my %h; grep !$h{ $_ }++, @list1, @list2 };
[download]