Re: File Properties/attributes in Win32

[rafl]

As the documentation of Win32::File says GetAttributes returns the or-ed combination of the file attributes

To chech if a given attribute is set or not you can use something like that:

my $attrib;
Win32::Fine::GetAttributes($path, $attrib);
if ($attrib & HIDDEN) { # HIDDEN and other attributes are
                        # exported by Win32::File by default
    print "$path is hidden\n";
}

Cheers, Flo

[BrowserUk]

# HIDDEN and other attributes are exported by Win32::File by default

Did you try that? If so, perhaps you could explain what I'm doing wrong here?

#! perl -slw
use strict;
use Win32::File qw[ GetAttributes ];

while( my $file = glob $ARGV[0] ) {
    GetAttributes( $file, my $attrs );
    printf "%1s%1s%1s%1s%1s%1s%1s%1s%1s %s\n",
        ( $attrs & ARCHIVE   ) ? 'A' : ' ',
        ( $attrs & COMPRESSED) ? 'C' : ' ',
        ( $attrs & DIRECTORY ) ? 'D' : ' ',
        ( $attrs & HIDDEN    ) ? 'H' : ' ',
        ( $attrs & NORMAL    ) ? 'N' : ' ',
        ( $attrs & OFFLINE   ) ? 'O' : ' ',
        ( $attrs & READONLY  ) ? 'R' : ' ',
        ( $attrs & SYSTEM    ) ? 'S' : ' ',
        ( $attrs & TEMPORARY ) ? 'T' : ' ',
        $file;
}
__END__
C:\test>junk4 *.pl
Bareword "ARCHIVE" not allowed while "strict subs" in use at C:\test\j
+unk4.pl line 7.
Bareword "COMPRESSED" not allowed while "strict subs" in use at C:\tes
+t\junk4.pl line 7.
Bareword "DIRECTORY" not allowed while "strict subs" in use at C:\test
+\junk4.pl line 7.
Bareword "HIDDEN" not allowed while "strict subs" in use at C:\test\ju
+nk4.pl line 7.
Bareword "NORMAL" not allowed while "strict subs" in use at C:\test\ju
+nk4.pl line 7.
Bareword "OFFLINE" not allowed while "strict subs" in use at C:\test\j
+unk4.pl line 7.
Bareword "READONLY" not allowed while "strict subs" in use at C:\test\
+junk4.pl line 7.
Bareword "SYSTEM" not allowed while "strict subs" in use at C:\test\ju
+nk4.pl line 7.
Bareword "TEMPORARY" not allowed while "strict subs" in use at C:\test
+\junk4.pl line 7.
Execution of C:\test\junk4.pl aborted due to compilation errors.

[rafl]

I didn't actually try it as I don't own a Win32 box, but the source code tells me that.

Exporter doesn't seem to import the symbols in @EXPORT if you specify a list of symbols yourself. You can either not import the GetAttributes function, import all attributes yourself or use the attributes with their full name.

I also think you could bug the author of the module to create an export tag that allows you to import all attributes at once.

Flo

[BrowserUk]

This is one of several of the Win32::* 'standard' modules I've encountered that have a pretty peculiar way of exporting constants.

In this case, they don't export the two quite specifically named functions into your namespace, but do export a dozen or so constants with very general names. But if you choose to import the function(s) you wish to use, the constants don't get exported!

That leaves you either fully qualifying them (as functions) or importing them manually, or using the functions fully qualified and having this random set of constants scribbled over your namespace!

To recap, you can do this:

#! perl -slw
use strict;
use Win32::File qw[ GetAttributes ];

while( my $file = glob $ARGV[0] ) {
    GetAttributes( $file, my $attrs );
    printf "%1s%1s%1s%1s%1s%1s%1s%1s%1s %s\n",
        ( $attrs & Win32::File::ARCHIVE()   ) ? 'A' : ' ',
        ( $attrs & Win32::File::COMPRESSED()) ? 'C' : ' ',
        ( $attrs & Win32::File::DIRECTORY() ) ? 'D' : ' ',
        ( $attrs & Win32::File::HIDDEN()    ) ? 'H' : ' ',
        ( $attrs & Win32::File::NORMAL()    ) ? 'N' : ' ',
        ( $attrs & Win32::File::OFFLINE()   ) ? 'O' : ' ',
        ( $attrs & Win32::File::READONLY()  ) ? 'R' : ' ',
        ( $attrs & Win32::File::SYSTEM()    ) ? 'S' : ' ',
        ( $attrs & Win32::File::TEMPORARY() ) ? 'T' : ' ',
        $file;
}

Or this:

#! perl -slw
use strict;
use Win32::File;

while( my $file = glob $ARGV[0] ) {
    Win32::File::GetAttributes( $file, my $attrs );
    printf "%1s%1s%1s%1s%1s%1s%1s%1s%1s %s\n",
        ( $attrs & ARCHIVE   ) ? 'A' : ' ',
        ( $attrs & COMPRESSED) ? 'C' : ' ',
        ( $attrs & DIRECTORY ) ? 'D' : ' ',
        ( $attrs & HIDDEN    ) ? 'H' : ' ',
        ( $attrs & NORMAL    ) ? 'N' : ' ',
        ( $attrs & OFFLINE   ) ? 'O' : ' ',
        ( $attrs & READONLY  ) ? 'R' : ' ',
        ( $attrs & SYSTEM    ) ? 'S' : ' ',
        ( $attrs & TEMPORARY ) ? 'T' : ' ',
        $file;
}

Or this:

#! perl -slw
use strict;
use Win32::File qw[ GetAttributes
    ARCHIVE COMPRESSED DIRECTORY HIDDEN NORMAL
    OFFLINE READONLY SYSTEM TEMPORARY
];

while( my $file = glob $ARGV[0] ) {
    GetAttributes( $file, my $attrs );
    printf "%1s%1s%1s%1s%1s%1s%1s%1s%1s %s\n",
        ( $attrs & ARCHIVE   ) ? 'A' : ' ',
        ( $attrs & COMPRESSED) ? 'C' : ' ',
        ( $attrs & DIRECTORY ) ? 'D' : ' ',
        ( $attrs & HIDDEN    ) ? 'H' : ' ',
        ( $attrs & NORMAL    ) ? 'N' : ' ',
        ( $attrs & OFFLINE   ) ? 'O' : ' ',
        ( $attrs & READONLY  ) ? 'R' : ' ',
        ( $attrs & SYSTEM    ) ? 'S' : ' ',
        ( $attrs & TEMPORARY ) ? 'T' : ' ',
        $file;
}

Or this:

#! perl -slw
use strict;
use Win32::File ();

while( my $file = glob $ARGV[0] ) {
    Win32::File::GetAttributes( $file, my $attrs );
    printf "%1s%1s%1s%1s%1s%1s%1s%1s%1s %s\n",
        ( $attrs & Win32::File::ARCHIVE()   ) ? 'A' : ' ',
        ( $attrs & Win32::File::COMPRESSED()) ? 'C' : ' ',
        ( $attrs & Win32::File::DIRECTORY() ) ? 'D' : ' ',
        ( $attrs & Win32::File::HIDDEN()    ) ? 'H' : ' ',
        ( $attrs & Win32::File::NORMAL()    ) ? 'N' : ' ',
        ( $attrs & Win32::File::OFFLINE()   ) ? 'O' : ' ',
        ( $attrs & Win32::File::READONLY()  ) ? 'R' : ' ',
        ( $attrs & Win32::File::SYSTEM()    ) ? 'S' : ' ',
        ( $attrs & Win32::File::TEMPORARY() ) ? 'T' : ' ',
        $file;
}

None of which seem particularly satisfactory from either a 'quick script-DWIM' or a software engineering point of view.

[blackadder]

I see,...

This answers my question....

....Thanks.