perl -MTie::File -MFcntl=O_RDONLY -le 'tie @array, "Tie::File", shift,
+ mode => O_RDONLY or die $!; print scalar @array' /etc/hosts
[download]

open (FILE, $ARGV[0]) or die "Can't open '$ARGV[0]': $!";
$lines++ while (<FILE>);
close FILE;
print "$lines\n";
[download]

don't need $lines -- $. does it for you (see perlvar)

perl -le 'open FILE, "/etc/passwd"; @_=<FILE>; print $.'
[download]

And (similar to QM's golf reply:

perl -lne 'END{print $.}' /etc/passwd
[download]

perl -pe '}{$_=$.' filename
[download]

Very tricky. So because of the }, the continue { print $_; } block is no longer attached to the loop, but to the {$_=$.} bare block. I never knew this trick with -p. (I knew about -ne '...}{...' but not what it did with -p.)

Yes. But -p and -n only differ by the continue/print. Compare -p:

> perl -MO=Deparse -pe"#stuff#"
LINE: while (defined($_ = <ARGV>)) {
    ();
}
continue {
    print $_;
}
[download]

to -n:

> perl -MO=Deparse -ne"#stuff#"
LINE: while (defined($_ = <ARGV>)) {
    ();
}
[download]

-QM
--
Quantum Mechanics: The dreams stuff is made of

Here's yet another golf variation, provided there's only one filename and that's a real filename (not a glob or something you can give to the two-arg open):

exec wc,-ll,pop
[download]

Hi try this,

#! /usr/bin/perl
use strict;
open(IN, "test.txt");
my @str = <IN>;
close(IN);
print scalar(@str);
[download]

Excuse my French, but why the **censored** would you store the whole file in memory just to count the lines? Why hardcode the filename in the script? Why bother to open and close the file, when <> is so handy?

Sorry, please forgive the tirade, I don't know what came over me. It must be the ghost of Abigail-II...Certainly TIMTOWTDI. (I find many of my cow-orkers skip over the "gather requirements" phase of programming, and jump headfirst into the shallow end of the implementation pool.)

While playing with this, I wanted to check how similar schemes work. For instance, don't do this either:

perl -e 'print scalar(()=<>),"\n"' filename
[download]

I tried this on a 300MB file, which took a long time (I waited several minutes before killing it), lots of memory, and started swapping to disk.

I tried the following on the same 300MB file, which took about 10 seconds, and never went above 2MB memory:

perl -pe "}{$_=$." filename
[download]

Inside a script, you could do this:

#!/your/perl/here -p
}{$_=$.
[download]

(yes, that compiles and runs too) though you may prefer the more conventional

#!/your/perl/here
use strict;
use warnings;
while (<>) {}
print "$.\n";
[download]

If you want to get fancy, and feed it more than one file at a time, keeping track of each file, try this:

#!/your/perl/here
use strict;
use warnings;
my $file_count = @ARGV;
while (<>) {}
continue
{ 
  if (eof)
  {
    # print file names for multiple files
    print "$ARGV: " if ($file_count > 1);
    print "$.\n";
    close ARGV;
  }
}
[download]

Someone will ask me for command line arguments to leave off the filenames, and provide summary statistics for multiple files. I'll leave that to OMAR. (Wow, there really is an OMAR! But he doesn't write much :(

-QM
--
Quantum Mechanics: The dreams stuff is made of

Sorry to have to submit a retraction but the one-liner I submitted before doesn't work. I was sure I had this one working but c'est la vie. Sorry to clutter the postings.

what about my($NumLines)=scalar <$Filename>

That only works if the current line just happens to contain a number which equals the number of lines. <> in scalar context just reads a single line.

But this works:

perl -wE'say~~(()=<>)' yourfile
[download]

while (sysread FILE, $buffer, 4096) {
        $lines += ($buffer =~ tr/\n//);
    }
[download]

Use:

while (<FILE>) {
  $lines++
}
[download]