You may view the original node and the consideration vote tally.

Yes, I did. All of the Wiki modules I found on CPAN are terrible. There doesn't seem to be any one flexible/powerful parser.

my $extractor;    # Must be a seperate statement.
$extractor = qr/
   \[\[
   (?:
      (?:  (?! \[\[ | \]\] ) .  )+
   |
      (??{ $extractor })
   )+
   \]\]
/x;

my @links = $text =~ /$extractor/g;
[download]

Optimized (I think):

my $extractor;    # Must be a seperate statement.
$extractor = qr/
   \[\[
   (?> (?:
      (?:
         (?> [^\[\]]+ )
      |
         \[ (?! \[ )
      |
         \] (?! \] )
      )
   |
      (??{ $extractor })
   )+ )
   \]\]
/x;

my @links = $text =~ /$extractor/g;
[download]

Tested.

Thank you for those regexes! I'll play around with them to see if I can get myself moving.

In the long run, I'd still like to know if Text::Balanced can be massaged into dealing with this situation. It does deal with <tags> and such..

The function to extract tagged data can indeed be used.

my @links;
my $extractor = gen_extract_tagged('[[', ']]', qr/(?:(?!\[\[).)*/);
for (;;) {
   (my $link, $text) = $extractor->($text);
   last if not defined $link;
   push(@links, $link);
}
[download]

Untested.

It's worth noting that ikegami's code is essentially a derivation of code in perlre for matching balanced parens:

$re = qr{
         \(
         (?:
            (?> [^()]+ )    # Non-parens without backtracking
          |
            (??{ $re })     # Group with matching parens
          )*
          \)
        }x;
[download]