Re: What is the best solution to swap input data?

[fenLisesi]

A few minor points that caught my attention:

• $a and $b are not the best variable names, as they are special
• You could use the replacement capability of substr to eliminate some temp vars
• In general, it is a good idea to unload args to a function as early as possible, so the shift statement would better become the first line
• It is a good idea to limit the scope of your vars as much as possible, so my ($a, $b) would be closer to home inside the for loop

use strict;
use warnings;

my @TEST_STRINGS
    = ( q(), qw(
                1 12 123 1234 12345
                )
        );
for my $t (@TEST_STRINGS) {
    printf qq(%-7s => "%s"\n), qq("$t"), swap( $t );
}
exit( 0 );

sub swap {
    my ($str) = @_;
    die 'No input?' unless defined $str;

    ## 0 to half-length minus one
    for my $i (0 .. (length( $str ) >> 1) - 1) {
        my $j = $i << 1;
        substr( $str, $j, 2, reverse substr( $str, $j, 2 ) );
    }
    return $str;
}

prints:

""      => ""
"1"     => "1"
"12"    => "21"
"123"   => "213"
"1234"  => "2143"
"12345" => "21435"

Cheers.

Update: Took sub swap {...} out of readmore