Re: Backticks and SIGALRM

[BrowserUk]

T'is easy with a thread:

#! perl -slw
use strict;
use threads;
use threads::shared;

$|++;

our $N ||= 11;
my $TIMEOUT = 10;
my $extApp = q[ perl -lwe"$|++; print $_ and sleep 1 for 1 .. $ARGV[0]
+" ];

my @results :shared;
my $pid :shared;

async {
    $pid = open my $fh, "$extApp $N |" or die "$!, $^E";
    @results = <$fh>;
}->detach;

kill 0, $pid while sleep 1 and $TIMEOUT--;
kill 3, $pid and warn 'Command timed out' if $TIMEOUT;

print "command return \n'@results'";

__END__
c:\test>junk6 -N=8
command return
'1
 2
 3
 4
 5
 6
 7
 8
'

c:\test>junk6 -N=10
command return
'1
 2
 3
 4
 5
 6
 7
 8
 9
 10
'

c:\test>junk6 -N=12
Command timed out at c:\test\junk6.pl line 21.
command return
'1
 2
 3
 4
 5
 6
 7
 8
 9
 10
 11
'

Wrapping that into a sub is left as an exercise.

[nemo]

BrowserUk,
Thanks for your reply, it's a working solution to the problem. :)
Many thanks for all replies.

Nemo

[BrowserUk]

YW. Here's a slightly cleaner implementation. The only caveat is that it abitrarially throws away any output received prior to the timeout occuring. Only you can decide how you want to signal timeout if you also wish to retrieve any partial output.

I guess this could form the basis of a whole CPAN module, but it just seems altogether too trivial for that?

#! perl -slw
use strict;

$|++;

my $extApp = q[ perl -lwe"$|++; print $_ and sleep 1 for 1 .. 10" ];

for my $timeout ( map $_*2, 4,5,6 ) {
    my @results = timedCommand( $extApp, $timeout );
    if( @results ) {
        print "Command returned\n", join '', @results;
    }
    else {
        print "Command timed out after $timeout seconds";
    }
}


sub timedCommand {
    use threads;
    use threads::shared;
    my( $cmd, $timeout ) = @_;

    my @results :shared;
    my $pid :shared;

    async {
        $pid = open my $fh, "$cmd |" or die "$!, $^E";
        @results = <$fh>;
    }->detach;

    kill 0, $pid while sleep 1 and $timeout--;
    kill 3, $pid and return if $timeout;
    return @results;
}
__END__
c:\test>junk6
Command timed out after 8 seconds
Command returned
1
2
3
4
5
6
7
8
9
10

Command returned
1
2
3
4
5
6
7
8
9
10

[nemo]

The only problem I had with your code was the sleep delay was too long. :) The script was executing over tens of thousands of files so in the end I used the implementation below.

sub executeTimed{
    my $cmd = shift;
    $|++;

    my @results :shared;
    my $pid :shared;
    async {
        $pid = open my $fh, "$cmd |" or die "$!, $^E";
        @results = <$fh>;
    }->detach;

    select(undef, undef, undef, 0.08);  
    my $test = kill (0, $pid);

    if($test){
        kill (3, $pid); 
        push(@results, "Function timed out.");
    }    
    return pop(@results);
}

Thanks again for all replies.
I was looking to use default active state perl package and was unsure if ipc-run would execute.

Nemo