Re: Date manipulations by inbuilt modules.

[moritz]

I don't know why you don't want to rely on perfectly good external modules, but here is a solution:

my $n = 60;
my @time_array = localtime($n * 24 * 3600 + time);

You can learn the meaning of the entries in @time_array from the localtime documentation.

[Anonymous Monk]

A good reason to use modules is that people make many mistakes when trying to reimplement the code, like you did. You incorrectly assumed all days are 24*60*60 seconds long. Solution:

use Time::Local qw( timegm );
my ($today_y, $today_m, $today_d) = (localtime())[5,4,3];
$today_m += 1;
$today_y += 1900;

# Use gmt for date arithmetic,
# even if the date is localtime.
my $today_date = timegm(0,0,0,$today_d,$today_m-1,$today_y);

# Every day *is* 24*60*60 long in GMT.
my $plus60_date = $today_date + 24*60*60 * 60;
my ($plus60_y, $plus60_m, $plus60_d) = (gmtime($plus60_date))[5,4,3];
$plus60_m += 1;
$plus60_y += 1900;

printf("Today:      %d/%02d/%02d\n", $today_y,  $today_m,  $today_d);
printf("In 60 days: %d/%02d/%02d\n", $plus60_y, $plus60_m, $plus60_d);

Today:      2007/08/28
In 60 days: 2007/10/27

- ikegami

[valavanp]

hi moritz,
thanks for your reply. If i want to use the Date::Calc module how should i do that. Thanks for your reply.

[andreas1234567]

$ perl -l
use strict;
use warnings;
use Date::Calc qw(Add_Delta_Days Today_and_Now);
my ($year,$month,$day,$hour,$min,$sec) = Today_and_Now();
print join(q{-},$year,$month,$day);
($year,$month,$day) = Add_Delta_Days($year,$month,$day,60);
print join(q{-},$year,$month,$day);
__END__
2007-8-28
2007-10-27